程序代码：

of = CREATEOBJECT("form1")
of.show(1)
RETURN

DEFINE CLASS form1 As Form
    Height = 500
    Width  = 900
    ADD OBJECT RT As Olecontrol WITH OleClass="RICHTEXT.RichtextCtrl.1",Top=10,Left=10,Width=200,Height=400
    ADD OBJECT LN as line WITH top=10,left=212,width=0,height=400,BorderWidth=1,BorderStyle=3,MousePointer=9
    ADD OBJECT WB As Olecontrol WITH OleClass="Shell.Explorer.2",Top=10,Left=215,Width=680,Height=400

    PROCEDURE Init
        this.rt.text = "RichtextCtrl"
        this.WB.Silent = 1
        thisform.WB.navigate2("https://bbs.bccn.net")
    ENDPROC
    
    PROCEDURE LN.MouseEnter(nButton, nShift, nXCoord, nYCoord)
        this.BorderWidth = 2
    ENDPROC  
     
    PROCEDURE LN.MouseLeave(nButton, nShift, nXCoord, nYCoord)
        this.BorderWidth = 1
    ENDPROC   

    PROCEDURE LN.MouseMove(nButton, nShift, nXCoord, nYCoord)
        IF (nButton == 1)
            IF !BETWEEN(nXCoord, thisform.rt.Left+1, thisform.wb.Left+thisform.wb.Width-3)
                RETURN 
            ENDIF
            thisform.LockScreen = .T.
            xx = nXCoord - this.Left
            this.Left = nXCoord
            thisform.rt.Width = thisform.rt.Width + xx
            thisform.wb.Left  = thisform.wb.Left  + xx
            thisform.wb.Width = thisform.wb.Width - xx
            thisform.LockScreen = .F.
        ENDIF 
    ENDPROC
ENDDEFINE

[此贴子已经被作者于2021-12-18 13:18编辑过]

[此贴子已经被作者于2021-12-18 17:11编辑过]