用5樓的代碼就可以了，平時顯示是零値爲空白，一旦Text1得到焦點，才會顯示出零。

继续等...

我试过了。 是这样的。 还有没有更好的办法了？

其它的方法還有。如果你想在接受輸入時也不顯示零，則用字符型方式接受輸入，在做其它處理時才將字符串轉爲數値用。我不知道你的應用到底想怎樣，知道才能有針對性地尋求解決辦法。

那就再请你帮帮。
我是想text1的值接收是数值型的。 也就是学号或代号
      text2的值接收是字符型的。
确定按钮是将这两个值添加到一个表里。

學號或代碼這類代碼，一般不應用數値型的。即使你Text1是數値型的代碼，不顯示零是什麽意思？看你15樓說的，這是很簡單的應用啊，是不是有什麽東西沒說清楚呀。

將文本框的値添加到表中，在Command1.Click代碼裏寫

REPLACE 字段1 WITH ThisForm.Text1.Value, 字段2 WITH ThisForm.Text2.Value

就可以了。

插入记录我用inset into可以了。
这个表单在没有得到焦点时是看不到0，在得到焦点时就会出来0.怎么记这个0在表单运行时也不显示出来。你不是说有其它的方法吗。那是什么？

把下面的代碼放在一個PRG文件中運行，看是不是要這種效果？

Form1 = CREATEOBJECT("my_Form")
Form1.Show
READ EVENTS
RETURN 

DEFINE CLASS my_Form AS Form 
    Caption = "文本框不顯示數値零"
    Height = 200
    Width = 300
    AutoCenter = .T.
    
    ADD OBJECT PROTECTED Text1 AS TextBox WITH Height = 25, Width = 100, Top = 5, Left = 5
    ADD OBJECT PROTECTED Text2 AS TextBox WITH Value = "", Height = 25, Width = 100, Top = 35, Left = 5
    ADD OBJECT PROTECTED Command1 AS CommandButton WITH Caption = "確定", Height = 25, Width = 60, Top = 65, Left = 5
    
    PROCEDURE Text1.Init
        WITH This
            .Value = ""
            .InputMask = "9999"
            .Alignment = 1
        ENDWITH 
    ENDPROC 
    
    PROCEDURE Text1.Valid
        WITH This
            .Value = TRANSFORM(VAL(.Value), .InputMask)
            IF EMPTY(VAL(.Value))
                .Value = ""
            ENDIF 
        ENDWITH 
    ENDPROC 
    
    PROCEDURE Command1.Click
        WITH This.Parent.Text1
            MESSAGEBOX("Text1.Value = " + TRANSFORM(VAL(.Value), .InputMask), 64, "")
        ENDWITH 
    ENDPROC 
    
    PROCEDURE Destroy
        CLEAR EVENTS 
    ENDPROC 
    
ENDDEFINE 

改一下，容易理解一些。對比看看改了哪裡？

Form1 = CREATEOBJECT("my_Form")
Form1.Show
READ EVENTS
RETURN 

DEFINE CLASS my_Form AS Form 
    Caption = "文本框不顯示數値零"
    Height = 200
    Width = 300
    AutoCenter = .T.
    
    ADD OBJECT PROTECTED Text1 AS TextBox WITH Height = 25, Width = 100, Top = 5, Left = 5
    ADD OBJECT PROTECTED Text2 AS TextBox WITH Value = "", Height = 25, Width = 100, Top = 35, Left = 5
    ADD OBJECT PROTECTED Command1 AS CommandButton WITH Caption = "確定", Height = 25, Width = 60, Top = 65, Left = 5
    
    PROCEDURE Text1.Init
        WITH This
            .AddProperty("TrueValue", 0)
            .Value = ""
            .InputMask = "9999"
            .Alignment = 1
            .SelectOnEntry = .T.
        ENDWITH 
    ENDPROC 
    
    PROCEDURE Text1.Valid
        WITH This
            .TrueValue = INT(VAL(.Value))
            .Value = IIF(EMPTY(.TrueValue), "", TRANSFORM(.TrueValue, .InputMask))
        ENDWITH 
    ENDPROC 
    
    PROCEDURE Command1.Click
        WITH This.Parent.Text1
            *
            * 使用Text1.TrueValue獲取眞値，顯示的.Value是字符型，.TrueValue才是數値型
            *
            MESSAGEBOX("Text1.Value = " + TRANSFORM(.TrueValue, .InputMask), 64, "")
        ENDWITH 
    ENDPROC 
    
    PROCEDURE Destroy
        CLEAR EVENTS 
    ENDPROC 
    
ENDDEFINE 

谢谢