现有 开支明细帐.dbf 我想动态生成 开支统计表.dbf
要求：
1、开支统计表中除“姓名”、“合计”字段外，其它字段由 开支明细帐.dbf中“支出明细”动态生成，具体字段数量不固定；
2、“合计”字段要放在最右边；
3、最后统计毎个学生支出金额，写入“合计”中。
【由于本人是新手，对vfp纯属个人爱好，不喜勿喷！】
请各位高手不吝赐教，万分感谢！！！

原始表：开支明细帐.dbf

结果表：开支统计表.dbf

[此贴子已经被作者于2025-10-20 16:00编辑过]

数据表设计不好，不便于统计

跟费用明细账那个贴是一个意思
看上去格式规范了，但看到后面，逗号又变成全角了，不知是否还有别的问题
楼上说的正是，数据表设计不好，其实就是源头没设计好
对于很随意的用户，你永远也不知道下一步他会做出什么来，所以你会有永远解决不完的问题

数据表已作修改，不知是否规范

       ***************
       * 名称：将开支明细转换成按物品清单列表
       * 来源：https://bbs.bc-/thread-514547-1-1.html
       * 时间：2025-10-21
       * 思路：因原表开支明细中的记录缺少规律，第一步将“,”号和“，”号进行统一，使之有规律性；
       *       第二步提取“物品”的名称；第三步创建统计表；第四步进行统计；第五步算合计。
       * ★★★★★★★★以上五步中有一个BUG，即 当“物品”的长度超过5个汉字，会出错★★★★★★★★
       ***************
       CLEAR 
       SET SAFETY off
       SET engi 70
       CLOSE DATABASES 
       
       SELECT * from 开支明细帐 into table ls
       SELECT ls
       REPLACE 支出明细 with STRTRAN(支出明细,[，],[,]) ALL   &&& 第一步完成
       zfc=[,]
       SELECT ls
       GO top
       SCAN
         fymx=支出明细
         n=OCCURS([元],fymx)
         k1=1
         FOR i=1 to n
           k2=AT([元],fymx,i)
           c_zf=SUBSTR(fymx,k1,k2-k1+2)               &&& 得到如“巧克力9元”的消费内容（后续作字段名用的）
           FOR j=1 to LEN(c_zf)
             IF SUBSTR(c_zf,j,1)$[0123456789.]
               k=j                                    &&& 得到 金额数字开始的位置值
               EXIT for 
             ENDIF 
           ENDFOR  
           aa=SUBSTR(c_zf,1,k-1)                      &&& 得到 物品名称
           IF !aa$zfc
             zfc=zfc+[0000000.00 as ]+aa+[,]          &&& 形成SQL语句中的字段列表
           ENDIF 
           k1=k2+3
         ENDFOR 
         SELECT ls
       ENDSCAN                                        &&& 第二步完成
       c_zdm=[姓名]+zfc+[合计]
       SELECT &c_zdm. from ls into table 开支统计表   &&& 第三步完成
       SELECT 开支统计表
       USE 开支统计表 alia bmk
       SELECT ls
       GO top
       SCAN
         fymx=支出明细
         n=OCCURS([元],fymx)                          &&& 记录要循环的次数
         k1=1
         FOR i=1 to n
           k2=AT([元],fymx,i)
           c_zf=SUBSTR(fymx,k1,k2-k1+2)               &&& 得到如“巧克力9元”的消费内容（后续作字段名用的）
           FOR j=1 to LEN(c_zf)
             IF SUBSTR(c_zf,j,1)$[0123456789.]
               k=j                                    &&& 得到 金额 数字开始的位置值
               EXIT for 
             ENDIF 
           ENDFOR  
           zdm=SUBSTR(c_zf,1,k-1)                     &&& 得到 物品名称
           aa=[]
           FOR ii=1 to LEN(c_zf)
             IF SUBSTR(c_zf,ii,1)$[0123456789.]
               aa=aa+SUBSTR(c_zf,ii,1)                &&& 得到 金额 文本
             ENDIF 
           ENDFOR 
           n_rmb=VAL(aa)                              &&& 金额文本转数值
           SELECT bmk
           LOCATE for bmk.姓名=ls.姓名
           IF FOUND()
             REPLACE ([bmk.]+zdm) with n_rmb          &&& 记录消费的金额
           ENDIF 
           k1=k2+3                                    &&& 确定 下一个 取词的起始位置值班
         ENDFOR 
         SELECT ls
       ENDSCAN                                        &&& 第四步完成
       SELECT bmk
       GO top
       SCAN
         sn=0
         FOR i=2 to FCOUNT()-1
           sn=sn+EVALUATE(FIELD(i))                   &&& 求得某人的消费金额和
         ENDFOR 
         REPLACE 合计 with ALLTRIM(TRANSFORM(sn,[]))+[元] &&& 写入合计数（王老师这次的开支明细表上合计字段 用了 “字符型” ！！！★★★ 真 的 讨 厌 ★★★）
         SELECT bmk
       ENDSCAN                                        &&& 第五步完成
       CLOSE DATABASES 
       QUIT 
       * 边试边写，已成功
       * 原始表中的开支明细记载方法 属于不可取的方法

王老师，要在初始数据表设计上下功夫，代码可以很简单的！
上午没什么事，帮你做了。其他人做代码是可以再精简一些的！

谢谢！！！

原始设计成这样，统计会很简单的

如何确保“合计”字段放在所有字段的最右边，请指点！

5楼代码中的这一句，让合计在最右边

你把这一句子中的姓名 与  合计  交换一下位置执行一下，打开表看看就知道了

[此贴子已经被作者于2025-10-21 12:36编辑过]

谢谢！我想将生成的“开支统计表.dbf”中的“合计”放到表的最后（最右边）显示，不知可行？另外，可否去掉小数部分，请赐教！

[此贴子已经被作者于2025-10-21 16:30编辑过]