遇到个复杂统计，但只会一句一句条件的统计，不能自动，太低效了，请高手帮忙实现自动提取数据并统计，实现效果如下图

[此贴子已经被作者于2023-8-9 11:55编辑过]

数据量非常庞大吗? Excel处理这种数据最高效。

ＶＦＰ中处理好再导入ＥＸＣＥＬ中

可先确定 bmddm 类型，然后再汇总统计，这是一思路，仅供参考！

试试：
CLOSE DATABASES
USE 2023信息 alia 信息
cStr1="SELECT xkkmzhdm,CNT(*) Zong"
cStr2="INSERT INTO Huizong(Xkkmzhdm,Zong"
cStr3="SELECT [合计],SUM(Zong)"
SELECT Bmddm,CNT(*) FROM 信息 GROUP BY Bmddm INTO CURSOR Bm
SCAN
    cStr1=cStr1+",SUM(IIF(!EMPTY("+Bmddm+")  AND Bmddm=["+Bmddm+"],1,0)) N"+Bmddm
    cStr2=cStr2+",N"+Bmddm
    cStr3=cStr3+",SUM(N"+Bmddm+")"
ENDSCAN
cStr1=cStr1+" FROM 信息 GROUP BY Xkkmzhdm INTO CURSOR Huizong READWRITE "
cStr2=cStr2+")"
cStr3=cStr3+" FROM Huizong"
ExecScript(cStr1)
ExecScript(cStr2+cStr3)
SELECT Huizong
BROWSE

USE 2023信息 ALIAS b2023
SELECT DISTINCT bmddm    FROM b2023 INTO ARRAY arr_bmddm
SELECT DISTINCT xkkmzhdm FROM b2023 ORDER BY xkkmzhdm INTO ARRAY arr_xkkmzhdm
cmd = "CREATE CURSOR tt (xkkmzhdm c(8),zong I"
FOR i=1 TO ALEN(arr_bmddm)
    cmd = cmd + "," + "_" + arr_bmddm[i] + " I"
ENDFOR
cmd = cmd + ")"
EXECSCRIPT(cmd)
APPEND FROM ARRAY arr_xkkmzhdm
INDEX on xkkmzhdm TAG xkkmzhdm
SELECT b2023
SET RELATION TO xkkmzhdm INTO "tt"  
SCAN 
    REPLACE tt.zong WITH tt.zong + 1, ("tt._"+b2023.bmddm) WITH EVALUATE("tt._"+b2023.bmddm) + 1
ENDSCAN
SELECT * FROM tt

[此贴子已经被作者于2023-8-9 21:09编辑过]

学习了！

高，学习啦，谢谢！

@fyyylyl @吹水佬 因出发未能用电脑，刚测试两个都符合要求，太感谢了 ，有些语句还不是很懂含义，继续学习。

@fyyylyl @吹水佬 本想结贴提供程序代码的两位高手，但不小心结贴散分点错了，请见谅。