如何用将下表

A522K0    22OK    C108，C301-C306，C411，C501

拆分成
A522K0    22OK    C108
A522K0    22OK    C301
A522K0    22OK    C302
A522K0    22OK    C303
A522K0    22OK    C304
A522K0    22OK    C305
A522K0    22OK    C306
A522K0    22OK    C411
A522K0    22OK    C501

CLEAR ALL
CLEAR 
DIMENSION aSplit[1]
cString = "C108, c301 -C306,A411,C501,"
IF Split(@aSplit, cString, "C") > 0
    FOR nIndex = 1 TO ALEN(aSplit, 1)
        ? aSplit[nIndex]
    NEXT 
ENDIF 
CLEAR ALL
RETURN 

FUNCTION Split(taSplit, tcString, tcBegin)
    LOCAL laTemp[1], lnBeginLength, lnLines, lnCount
    
    lnBeginLength = LEN(tcBegin)
    lnCount = 0
    lnLines = ALINES(laTemp, tcString, 1+4+8, ",")
    IF lnLines > 0
        LOCAL lnLine
        FOR lnLine = 1 TO lnLines
            IF UPPER(LEFT(laTemp[lnLine], lnBeginLength)) == UPPER(tcBegin)
                lnCount = lnCount + 1
                DIMENSION taSplit[lnCount]
                LOCAL lnPos
                lnPos = AT("-", laTemp[lnLine])
                IF lnPos > 0
                    taSplit[lnCount] = LEFT(laTemp[lnLine], lnPos - 1)
                    LOCAL lnFrom, lnTo, lnIndex
                    lnFrom = VAL(SUBSTR(laTemp[lnLine], lnBeginLength + 1, lnPos - lnBeginLength - 1)) + 1
                    lnTo = VAL(SUBSTR(SUBSTR(laTemp[lnLine], lnPos + 1), lnBeginLength + 1))
                    FOR lnIndex = lnFrom TO lnTo
                        lnCount = lnCount + 1
                        DIMENSION taSplit[lnCount]
                        taSplit[lnCount] = tcBegin + TRANSFORM(lnIndex)
                    NEXT 
                ELSE
                    taSplit[lnCount] = laTemp[lnLine]
                ENDIF 
            ENDIF 
        NEXT 
    ENDIF 

    RETURN lnCount
    
ENDFUNC 

[此贴子已经被作者于2015-12-7 23:09编辑过]

上传表看看

得到aSplit[]数组之后，循环给目标表添加记录即可。注意我示例中修改过的传入字符串，有各种容错，以及排除不需要数据的成分。除非你的数据够变态，否则大部分的容错都考虑到了。

[此贴子已经被作者于2015-12-7 23:31编辑过]

简单点，自己修改下即可

CLEAR
cStr="C108，C301-C306，C411，C501"
nCOL=ALINES(ACSTR,CSTR,"，")

FOR I=1 TO nCOL
    A1=ACSTR[I]
    IF "-"$A1
        =ALINES(AA,A1,"-")
        FOR J=VAL(SUBSTR(AA[1],2)) TO VAL(SUBSTR(AA[2],2))
            ?"C"+STR(J,3)
        ENDFOR
    ELSE
        ?A1
    ENDIF
ENDFOR

[此贴子已经被作者于2015-12-7 23:31编辑过]

ALINES(aa1, "A522K0    22OK    C108,C301-C306,C411,C501", 4, " ")
ALINES(aa2, aa1[3], ",")
FOR EACH aa2i IN aa2
    ALINES(aa3, aa2i, "-")
    FOR i = VAL(RIGHT(aa3[1],3)) TO VAL(RIGHT(aa3[ALEN(aa3)],3))
        ? aa1[1], aa1[2], "C"+TRANSFORM(i)
    ENDFOR
ENDFOR  

sz = "A522K0    22OK    C108,C301-C306,C411,C501"
ALINES(aa1, strt(sz, "C", ""), 4, " ")
ALINES(aa2, aa1[3], ",")
FOR EACH aa2i IN aa2
    ALINES(aa3, aa2i, "-")
    FOR i = VAL(aa3[1]) TO VAL(aa3[ALEN(aa3)])
        ? aa1[1], aa1[2], "C"+TRANSFORM(i)
    ENDFOR
ENDFOR  

谢谢大家，新手我没表达清楚，上传表，请各位高手再帮下，谢谢!

这样的拆分应该是基本功能，没有什么难度，参考帮助文件或者教材应该可以做到的。

意思要表达清楚