请问各位老师，我想在表单中通过文本框中的“身份证号”在另一文本框显示“出生日期”。不知如何实现？

if len(sfzh)=18
thisfrom.text2.value=subs(sfzh,7,8)
else
thisfrom.text2.value='19'+subs(sfzh,7,6)
endif

?SUBSTR(sfzh,7,IIF(LEN(sfzh)=18,8,6))

用substr()从身份证号中截取出生日期

谢谢老师们支招，我是想取日期型的“1985-01-26”，而不是字符型的“19850126”。再请帮忙，谢谢！

Text2.When 事件
Sfzh=Substr(Alltrim(Thisform.Text1.Vaule),7,8) && 以18位身份证为例
Thisform.Text2.Value=Ctod(Transform(Sfzh,"@R 9999-99-99"))

[ 本帖最后由 sdta 于 2014-7-27 02:54 编辑 ]

如果是16、17位，上面代码是要出错的，如果要保证身份证号码的长度为18位或15位，要加判断条件

如何判断呢？对不起，我是个初学者

Form.Init 事件

Thisform.AddProperty("Sfzh","") && 为表单增加一个属性，用于保存Text1.Value

Text1.Valid 事件

With Thisform
    .Sfzh=Alltrim(.Text1.Value)
    * 判断.Text1.Value 值中是否有非数字字符
    If Len(Chrtran(.Sfzh,"0123456789",""))!=0
       =Messagebox("身份证中含有非数字字符")
       Return .Text1
    Endif 
    * 判断身份证长度
    If Not Inlist(Len(.Sfzh),15,18)
       =Messagebox("身份证长度必须 15位或18位")
       Return .Text1
    Endif

    .Sfzh=Iif(Len(.Sfzh)=18,Substr(.Sfzh,7,8),"19"+Substr(.Sfzh,7,6))
    * 判断年份
    If Not Between(Val(Left(.Sfzh,4)),1900,Year(Date()))
        =Messagebox("年份必须在 1900-"+Transform(Year(Date()))+" 之间")
        Return .Text1
    Endif 
    * 判断月份
    If Not Between(Val(Substr(.Sfzh,5,2)),1,12)
        =Messagebox("月份必须在 1-12 之间")
        Return .Text1
    Endif 
    * 判断日
    nDay=Day(Gomonth(Date(Val(Left(.Sfzh,4)),Val(Substr(.Sfzh,5,2)),1),1)-1)
    If Not Between(Val(Substr(.Sfzh,7,2)),1,nDay)
        =Messagebox("天数必须在 1-"+Transform(nDay)+" 之间")
        Return .Text1
    Endif 
Endwith 

Text2.Gotfocus

Thisform.Text2.Value=Ctod(Transform(Thisform.Sfzh,"@R 9999-99-99"))

上面只是简单的判断

[ 本帖最后由 sdta 于 2014-7-27 02:56 编辑 ]

在有完整的身份证历史数据表的基础上，
1.判断地址码是否存在
2.判断输入的身份证第17位性别码是否正确
3.判断18位身份证的校验码是否正确
有关身份证相关知识请参考https://bbs.bccn.net/thread-382165-1-1.html

上面所有判断都是正确的，只能说明录入的身份证号码是正确的，但不能说明是合法的。

上面的判断代码可以到网上搜索，在此就不写了。

[ 本帖最后由 sdta 于 2014-7-27 03:14 编辑 ]