如何获取所有系统桌面文件、开始菜单路径？
文件路径会存在于2个文件夹中：C:\Documents and Settings\Administrator  以及C:\Documents and Settings\All Users


-

不晓得朋友要派啥用场

DECLARE LONG SHGetSpecialFolderLocation IN shell32.dll LONG, LONG, LONG@
DECLARE LONG SHGetPathFromIDList IN shell32.dll LONG, STRING@
? _GetFolder(0)
? _GetFolder(11)

FUNCTION _GetFolder(nFolder)
    LOCAL ppidl, lpsbuf
    ppidl = 0
    lpsbuf = SPACE(256)
    SHGetSpecialFolderLocation(0, nFolder, @ppidl)
    SHGetPathFromIDList(ppidl, @lpsbuf)
    RETURN LEFT(lpsbuf,AT(0h00,lpsbuf)-1)
ENDFUNC

也可用 SHGetSpecialFolderPath()
DECLARE LONG SHGetSpecialFolderPath IN shell32.dll LONG, STRING@, LONG, LONG
#define CSIDL_DESKTOP  0x0000
#define CSIDL_STARTMENU  0x000b
? _GeSysPath(CSIDL_DESKTOP)
? _GeSysPath(CSIDL_STARTMENU)
CREATE CURSOR tt (CSIDL I, PATH C(240))
FOR i=0 TO 60
    INSERT INTO tt VALUES (i, _GeSysPath(i))
ENDFOR
GO TOP
BROWSE


FUNCTION _GeSysPath(nFolder)
    LOCAL cPath
    cPath = SPACE(260)
    IF SHGetSpecialFolderPath(0, @cPath, nFolder, 0) == 0
        RETURN "<NULL>"
    ENDIF
    RETURN LEFT(cPath, AT(0h00,cPath)-1)
ENDFUNC

谢谢，收藏了。

谢谢吹水版主！