简单示例，参考修改一下应该能用。

** test.prg
CREATE CURSOR tt (f1 C(10), f2 C(10), f3 I, f4 I)
INSERT INTO tt VALUES ("ABC", "123456", 101, 111)
INSERT INTO tt VALUES ("DEF", "654321", 202, 222)
INSERT INTO tt VALUES ("GHI", "456123", 303, 333)
INSERT INTO tt VALUES ("JKL", "789456", 404, 444)
INSERT INTO tt VALUES ("NMO", "123789", 505, 555)
GO TOP 
of = CREATEOBJECT("form1")
of.show(1)
RETURN

DEFINE CLASS form1 AS Form
    AutoCenter = .T.
    TextValue = ""
        
    ADD OBJECT Grid1 AS Grid WITH width=this.Width 
        
    PROCEDURE Grid1.Init
        FOR EACH oColumn IN this.Columns
            BINDEVENT(oColumn.Text1, "RightClick",  thisform, "myRightClick")
        ENDFOR
    ENDPROC 
    
    PROCEDURE myRightClick
        IF (AEVENTS(aObj, 0) > 0)
            IF (PROPER(aObj[1].BaseClass) == "Textbox")
                myPop(thisform, aObj[1])
            ENDIF
        ENDIF
    ENDPROC
ENDDEFINE

FUNCTION myPop(oForm1, oText)
    DEFINE POPUP pop FROM MROW(),MCOL()
    DEFINE BAR 1 OF pop PROMPT '复制'
    DEFINE BAR 2 OF pop PROMPT '粘贴'
    ON SELECTION POPUP pop mySelpop(POPUP(), PROMPT(), oForm1, oText)
    ACTIVATE POPUP pop
    DEACTIVATE POPUP pop
    RELEASE POPUP pop
ENDFUNC

FUNCTION mySelpop(cPopup, cPrompt, oForm1, oText)
    DO CASE
        CASE cPrompt == "复制"
            oForm1.TextValue = oText.Value
        CASE cPrompt == "粘贴"
            IF !EMPTY(oForm1.TextValue)
                IF VARTYPE(oForm1.TextValue) == VARTYPE(oText.Value)
                    oText.Value = oForm1.TextValue
                ELSE
                    IF (VARTYPE(oText.Value) == "N")
                        oText.Value = VAL(oForm1.TextValue)
                    ELSE
                        oText.Value = TRANSFORM(oForm1.TextValue)
                    ENDIF
                ENDIF
            ENDIF
        OTHERWISE
    ENDCASE
    DEACTIVATE POPUP (cPopup)
    RELEASE POPUP (cPopup)
ENDFUNC

想简单一点的话，哪里需要右键鼠标复制黏贴等，你就把下列代码，复制到对应的那个控件的 rightclick 中。

 DEFINE POPUP popRight SHORTCUT RELATIVE FROM MROW(),MCOL()
 DEFINE BAR _med_cut OF popRight PROMPT "剪切(\<T)"
 DEFINE BAR _med_copy OF popRight PROMPT "复制(\<C)"
 DEFINE BAR _med_paste OF popRight PROMPT "粘贴(\<P)"
 DEFINE BAR _med_clear OF popRight PROMPT "删除(\<D)"
 ACTIVATE POPUP popRight

在GIRD里无法实现，右键鼠标复制,

*1、在表单新建立1个事件，名称为 MyRightClick,内容如下
*thisform.MyRightClick
DEFINE POPUP popRight SHORTCUT RELATIVE FROM MROW(),MCOL()
DEFINE BAR _med_cut OF popRight PROMPT "剪切(\<T)"
DEFINE BAR _med_copy OF popRight PROMPT "复制(\<C)"
DEFINE BAR _med_paste OF popRight PROMPT "粘贴(\<P)"
DEFINE BAR _med_clear OF popRight PROMPT "删除(\<D)"
ACTIVATE POPUP popRight

*2、在表单拉出1个表格，名称为 Grid1,在 Grid1.init中
*thisform.grid1.init
CREATE CURSOR t1(姓名 c(10),地址 C(20),年龄 n(3))
INSERT INTO t1(姓名,地址,年龄) VALUES('张三','北京市XX路XX号',99)
INSERT INTO t1(姓名,地址,年龄) VALUES('李四','南京市XX路XX号',60)
this.RecordSourceType = 1
this.RecordSource =ALIAS()
*这段的作用是，绑定自己定义的事件 MyRightClick 到 Grid1的所有 Text1.RightClick中去。
FOR EACH oColumn IN this.Columns
    BINDEVENT(oColumn.Text1, "RightClick", thisform, "myRightClick")
ENDFOR

谢各位大神热心相助，
采用mywisdom88搞好了，虽然不能在表中操作，但也是一个变通可行的方案，解决了问题。
再谢mywisdom88一次！！！！！！！！

大神吹水佬的应该也可以，只是自已太浅了，要慢慢研究才行了，谢了!!!

不要谢我，要谢吹斑竹的，我是根据他的代码，整理出来给你看的。。

果真如此，吹斑竹这一句：
PROCEDURE Grid1.Init
         FOR EACH oColumn IN this.Columns
             BINDEVENT(oColumn.Text1, "RightClick",  thisform, "myRightClick")
         ENDFOR
     ENDPROC
是关键

在表单中是无法自定义事件的，但可以自定义属性及方法。

多谢矫正。是自定义方法 thisform.MyRightClick