请教先生:
我想将表内的整行作不同的排列,现表中只有5行,按全排列知识排成后的结果共应该是120行,可我用代码运行下来怎么会有201600行,请先生指点(代码及表在附件中),谢谢

是不是这样：

**
** 从n个数中任取m个数的排列
** 当m=n时所有的排列叫全排列
**
n = 5
m = n
CREATE CURSOR tt (ni I)
FOR i = 1 TO n
    INSERT INTO tt Values(i)
ENDFOR
sSELECT = ""
sFROM   = ""
sWHERE  = ""
FOR i = 1 TO m
    sSELECT = sSELECT + ",a"+TRANSFORM(i)+".ni 列"+TRANSFORM(i)
    sFROM   = sFROM   + ",tt a"+TRANSFORM(i)
    IF i < m
        ss = ""
        FOR j = i TO m
            ss = ss + ",a"+TRANSFORM(j)+".ni"
        ENDFOR
        sWHERE  = sWHERE + " AND !INLIST("+SUBSTR(ss,2)+")"
    ENDIF
ENDFOR
EXECSCRIPT("SELECT " + SUBSTR(sSELECT,2) + " " +;
           "FROM "   + SUBSTR(sFROM,2)   + " " +;
           "WHERE "  + SUBSTR(sWHERE,6)  + " " +;
           "INTO CURSOR tmp")
BROWSE NOWAIT
MESSAGEBOX("从"+TRANSFORM(n)+"个数中任取出"+TRANSFORM(m)+"个数的排列共 " + TRANSFORM(RECCOUNT()) + " 种")

排列数的计算公式是：
P(r, n) = n! / (n - r)!

全排列数的计算公式是：
P(n) = n!

VFP 代码：
Clear
? Factorial(5)  && n!  && 5 的全排列是 120
 
Function Factorial( nNumber As Integer )
    Local nResult
    If nNumber = 0
        nResult = 1
    Else
        nResult = nNumber * Factorial( nNumber - 1 )
    Endif
    Return nResult
Endfunc


 

Clear
Permutation("12345")
*!*    Permutation("BRAD")
*!*    Permutation("ABCDEFGHIJ")  && 警告... 将产生 3.5 百万数的组数!



Function Permutation(tcWord, tcPrefix)  && 排列计算
    If Empty(tcPrefix)
        Clear
        tcPrefix = ""
    Endif

    Do Case
        Case Len(tcWord) = 0
            * 不计算
        Case Len(tcWord)=1
            ?? tcPrefix + tcWord + " "
        Otherwise
            Local xx
            For xx = 1 To Len(tcWord)
                Permutation(Left(tcWord, xx - 1) + Substr(tcWord, xx + 1), tcPrefix + Substr(tcWord, xx, 1))
            Endfor
    Endcase
Endfunc

留足学习，谢谢

楼主想用 SQL-Select 语句计算排列和组合的算法，是吗？
好像可以的，下午我试试看。

*!*    5 个数的全排列 (SQL-Select 算法)：
Clear
Create Cursor P1 (Num C(1), Digit I)
Insert Into P1 Values ('1', 1)
Insert Into P1 Values ('2', 2)
Insert Into P1 Values ('3', 4)
Insert Into P1 Values ('4', 8)
Insert Into P1 Values ('5',16)

Select Distinct P1.Num + P2.Num + P3.Num + P4.Num + P5.Num As 排列数 From ;
    P1 P1, P1 P2, P1 P3, P1 P4 , P1 P5 ;
    Where P1.Digit + P2.Digit + P3.Digit + P4.Digit + P5.Digit = 31 ;
    Order By 1
? "全排列有 : " + Transform(Reccount())

Clear
Create Cursor Colour (Color C(10))
Insert Into Colour Values ('红')
Insert Into Colour Values ('黑')
Insert Into Colour Values ('白')
Insert Into Colour Values ('绿')
Insert Into Colour Values ('橙')

*!*    组合 : 5 选 2 --> 10 种组合
Select a.Color As 颜色1, b.Color As 颜色2 ;
    FROM  Colour a ;
    JOIN Colour b ;
    ON a.Color < b.Color
? Reccount()


*!*    排列 :  5 选 2 --> 20 种排列
Select a.Color As 颜色1, b.Color As 颜色2 ;
    FROM Colour a ;
    JOIN Colour b ;
    ON a.Color != b.Color

? Reccount()

*!*    5 个数的全排列 (SQL-Select 算法 2)：

Clear
Create Cursor P1 (Id C(1))
Insert Into P1 Values ('1')
Insert Into P1 Values ('2')
Insert Into P1 Values ('3')
Insert Into P1 Values ('4')
Insert Into P1 Values ('5')

*!*    5 的全排列 :  120 种排列
Select a.Id As 列1, b.Id As 列2, c.Id As 列3, d.Id As 列4, e.Id As 列5 ;
    From P1 a, P1 b, P1 c, P1 d, P1 e ;
    Where a.Id != b.Id And a.Id != c.Id And a.Id != d.Id And a.Id != e.Id And ;
    b.Id != c.Id And b.Id != d.Id And b.Id != e.Id And ;
    c.Id != d.Id And c.Id != e.Id And ;
    d.Id != e.Id ;
    Order By 列1, 列2, 列3, 列4, 列5
? Reccount()

楼主帖子中的附件好像是对版主：SDTA 发问的，请 SDTA 老师做归纳性、权威性的指教，谢谢。

网友sdta.prg