如：xm           dz            bz
     a            ssdd         aa
     a            ssdd         bb
     a            ssdd         cc
     b            ssdd         b1
     b            ssdd         a1
整理成：
    xm           dz          bz
    a            ssdd       aa,bb,cc
    b            ssdd        b1,a1
该如何写程序啊？

假设楼主的数据表是oky.dbf：
SELECT distinc xm,SPACE(27) dz,SPACE(17) bz FROM c:\oky INTO cursor temp READWRITE
SELECT oky
FOR i=1 TO RECCOUNT()
  GO i
  UPDATE temp SET bz=ALLTRIM(bz)+IIF(EMPTY(bz),"",',')+oky.bz,dz=oky.dz,xm=oky.xm WHERE temp.xm=oky.xm
NEXT
SELECT temp
BROWSE

 

[ 本帖最后由 qjbzjp 于 2012-11-14 10:59 编辑 ]

收到的鲜花

• 月沐庭轩 于 2012-11-14 20:10 送鲜花  10朵   附言：我很赞同

xm,SPACE(27) dz,SPACE(17)这是什么意思，不懂

xm是指姓名字段
space(27)是指增加一个空字段，字符型，长度为27

xm,SPACE(27) as dz && 生成一个长度为27个空格，名为dz的字段，这里的 as 可以省略。

CLOSE ALL
SET SAFETY OFF

CREATE TABLE T2 FREE ;
   (Xm C(1), Dz C(4), BZ C(20))

SELECT 0
USE T1
INDEX ON Xm+Dz TAG XmDz
GO TOP
SCAN
   参照关键字=T1.Xm+T1.Dz
   IF RECCOUNT("T2")=0
      INSERT INTO T2 VALUES (T1.Xm, T1.Dz, T1.Bz-"，")
   ELSE
      IF T2.Xm+T2.Dz=参照关键字
         GO BOTTOM IN T2
         REPLACE T2.Bz WITH T2.Bz-T1.Bz-"，"
      ELSE
         SELECT T2
         GO BOTTOM
         REPLACE T2.Bz WITH LEFTC(T2.Bz,LENC(ALLTRIM(T2.Bz))-1)
         INSERT INTO T2 VALUES (T1.Xm, T1.Dz, T1.Bz-"，")
         SELECT T1
      ENDIF
   ENDIF
ENDSCAN

SELECT T2
GO BOTTOM
REPLACE T2.Bz WITH LEFTC(T2.Bz,LENC(ALLTRIM(T2.Bz))-1)

SET SAFETY ON
CLOSE ALL
RETURN 

此程序段可以在不确定重复记录数，且重复记录没有排过序的情况下通用。




[ 本帖最后由 taifu945 于 2012-11-14 12:48 编辑 ]

收到的鲜花

• 月沐庭轩 于 2012-11-14 20:09 送鲜花  10朵  

上面代码可改为

SELECT DISTINCT XM,DZ,SPACE(20) BZ FROM OKY INTO CURSOR TEMP READWRITE
SELECT OKY
SCAN
    UPDATE TEMP SET BZ=ALLTRIM(BZ)+IIF(EMPTY(BZ),[],[,])+OKY.BZ WHERE TEMP.XM==OKY.XM AND TEMP.DZ==OKY.DZ
ENDSCAN
SELECT TEMP
BROWSE

[ 本帖最后由 bccn201203 于 2012-11-14 13:15 编辑 ]

收到的鲜花

• 月沐庭轩 于 2012-11-14 20:10 送鲜花  10朵