VFP6.0

请直接将一楼的代码复制过去再试试看，VFP6.0应该可以运行的。如果是9.0可以直接从代码上看的出命令和函数名是否正确，因为这些关键字都是用蓝色显示的。

oExcel = CreateObject("excel.application") &&创建 EXCEL 实例对象
With oExcel
    .Workbooks.Add                           && 增加一个工作薄
    .Sheets("Sheet1").Select
    .Sheets("Sheet1").Name = "sample"       && 改变SHEET名称
    .Cells.Select                           && 全选工作簿
    With .Selection.Font
         .Name = "宋体"
         .Size = 10
    EndWith
ENDWITH
SELECT * FROM GZ INTO CURSOR TMP
JLS=TRANSFORM(RECCOUNT()+1)
oExcel.ActiveSheet.Rows(1).RowHeight=24   &&设置第1行至最后一行的高度
oExcel.ActiveSheet.Rows('2:&JLS').RowHeight=20
FOR I=1 TO FCOUNT()
    MFIELD=FIELD(I)
    OEXCEL.ActiveSheet.Columns(I).ColumnWidth=FSIZE(FIELD(I))  && 列的宽度(单位：字符个数)
    OEXCEL.Cells(1,I).Value=FIELD(I) && 设置单元格的值（可以是字符串变量，表字段名）
    OEXCEL.selection.HorizontalAlignment=3
    FOR J=1 TO RECCOUNT()
        GO J
        OEXCEL.Cells(J+1,I).Value=&MFIELD
    ENDFOR
ENDFOR
OEXCEL.visible = .T. && 可见

VFP导入EXCEL：这段代码虽然不怎么精练，也有一定的缺限，但不受打开的EXCEL影响，运行正常。

[ 本帖最后由 sdta 于 2012-5-17 21:38 编辑 ]

谢谢

这段代码并无特别之处，同样也会受到打开EXCEL操作的影响。只不过通常读写操作仅在短时间就完成了，用户还来不及去打开其他的EXCEL文件，所以也就没有出现受影响的问题。

小结：
1、在VFP对EXCEL文件操作的时候，用户打开或关闭EXCEL文件，都有可能会对VFP的操作出现影响。
2、之所以说是可能，而不是说肯定，这与打开EXCEL使用的进程相关。比如说在VFP操作EXCEK之前，如果用户已经打开了EXCEL文件，然后在这个进程（窗口）中用打开菜单来打开其他的EXCEL文件，就不会对VFP的操作发生影响。此时如果再用点击EXCEL文件方式打开，有时也不会对VFP的操作产生影响。
3、在VFP对EXCEL操作时，如果用户关闭了所有已经打开的EXCEL进程时，也可能会对VFP的操作产生影响，导致出错中断。
4、打开EXCEL文件对VFP操作的影响不仅仅是读操作，也会影响到写操作。我有次在VFP对EXCEL文件添加一个表，然后向新增的表写入内容时，正好打开另一个EXCEL文件，新增的表竟然被添加到新打开的EXCEL文件中。
5、总之，这个影响可能与进程有关，如果当前活动的进程不是VFP操作时申请的进程，则不会受影响；反之则必定会受影响。

欢迎各位对以上的小结拍砖！

表中记录少还免强

学习了

IF USED()
    nrecc=RECCOUNT()
    NEWEXCEL=CREATEOBJECT("EXCEL.APPLICATION")    &&建立EXCEL文件
    WITH NEWEXCEL
        .WORKBOOKS.ADD                            &&添加新EXCEL表
        nFd=AFIELDS(aTitl)                        &&取总字段数及各字段名、属性等
        FOR I = 1 TO nFd
            .CELLS(1,I)=ALLTRIM(aTitl(I,1))       &&将数组中的标题写入第一行
        ENDFOR
    ENDWITH
    GOTO TOP
    nHbh=2
    ON ERROR .CELLS(nHbh,I)="---"
    DO WHILE !EOF()                               &&开始对记录的循环
        WAIT WINDOW '共有'+ALLTRIM(STR(nrecc))+'条记录，正在转换第'+ALLTRIM(STR(RECNO()))+'条记录...' NOWAIT
        FOR I = 1 TO nFd                          &&对记录中的每个字段进行处理
            cFild=ALLTRIM(aTitl(I,1))             &&组成“表名.字段名”
            cFild=&cFild
            IF VARTYPE(cFild)="N"
                IF cFild#0
                    NEWEXCEL.CELLS(nHbh,I)=cFild  &&数值不为零则写入，
                ENDIF
            ELSE
                IF VARTYPE(cFild)="C"
                    cFild=RTRIM(cFild)            &&字符字段则截去尾部空格
                    NEWEXCEL.CELLS(nHbh,I).NumberFormatLocal="@"&&设置单元格属性为文本
                ENDIF
                NEWEXCEL.CELLS(nHbh,I)=cFild
            ENDIF
        ENDFOR
        nHbh=nHbh+1
        SKIP
    ENDDO
    MESSAGEBOX("数据导出已经完成，请注意保存文件！",64,"操作提示")
    NEWEXCEL.ACTIVESHEET.PAGESETUP.ORIENTATION=1
    NEWEXCEL.VISIBLE=.T.                          &&显示excel表以便继续编辑和保存
    ON ERROR
ELSE
    MESSAGEBOX('当前工作区没有打开的表！',64,'系统提示：')
ENDIF
RETURN