程序代码：

*--------------------------------
* 批量刪除文件
* 參數：cDirectory    -- 文件所在目錄字符串（無需用\號結尾）
*       cFileSkeleton -- 文件通配符
* 返回：操作成功返回.T.否則爲.F.
*--------------------------------
FUNCTION Delete_All_File(cDirectory AS Character, cFileSkeleton AS Character) AS Boolean 
    
    IF EMPTY(cDirectory)
        *-----------------------
        * 如果沒有傳入cDirectory參數則使用由SET DEFAULT TO指定的默認目錄
        *-----------------------
        cDirectory = SET("Default")
    ENDIF 
    cDirectory = ADDBS(cDirectory)        && 在末尾添加反斜線
    
    IF EMPTY(cFileSkeleton)
        *-----------------------
        * 如果沒有傳入cFileSkeleton參數則默認爲*.*
        *-----------------------
        cFileSkeleton = "*.*"
    ENDIF 
    
    LOCAL aFiles[1,5]
    IF ADIR(aFiles, cDirectory + cFileSkeleton) > 0
        LOCAL nIndex AS Integer, cFile AS Character
        FOR nIndex = 1 TO ALEN(aFiles,1)
            cFile = cDirectory + aFiles[nIndex,1]
            DELETE FILE "&cFile"        && 爲確保能夠刪除帶空格之類長文件名的文件，用雙引號把文件名括起來
        NEXT 
        RETURN .T.
    ELSE 
        *----------------------
        * 沒有文件
        *----------------------
        RETURN .F.
    ENDIF 
    
ENDFUNC