大家好，请帮帮我这忙吧：
我想获取我指定的路径下的所有文件夹的名字，应该怎么作啊？非文件夹的不要！

有个DIRLISTBOX，好像是这个，你看看

Private Sub get_folders(ByRef List1 As ListBox, ByVal path As String)
    Dim fso As New Scripting.FileSystemObject
    Dim fd As Scripting.Folder
    Dim fd_1 As Scripting.Folder
   
    Set fd = fso.GetFolder(path)
   
    For Each fd_1 In fd.SubFolders
        DoEvents
        List1.AddItem fd_1.path
        get_folders List1, fd_1.path
    Next
End Sub

Private Sub Command1_Click()
    get_folders List1, "D:"
End Sub

Private Sub Form_Unload(Cancel As Integer)
    Unload Me
    End
End Sub

能不能什么控件都不用，来获得所有的文件夹的名字？

Private Sub Command1_Click()
Dim i As String
Dim pathstr As String

pathstr = "d:\"     '父目录
i = Dir(pathstr, vbDirectory)       '取第一个
Do While i <> ""                    '不为空就循环
   If i <> "." And i <> ".." Then   '如果不是 当前目录及上一级目录 . 及 ..
        If (GetAttr(pathstr & i) And vbDirectory) = vbDirectory Then        '是否是目录
            List1.AddItem i         '确定是目录,添加到列表,这里可以自己处理
        End If
    End If
    i = Dir      '取下一个
Loop

End Sub

[[it] 本帖最后由 风吹过b 于 2008-11-26 11:08 编辑 [/it]]

用FSO

ok,可以了，谢谢大家！
特别谢谢风吹过b
呵呵