如题。欢迎暴力测试，找出bug！

10/12再次更新代码如下：
解决selstart值不正确的问题
弃用inputmask，它限制了输入格式

**************************************************
*-- 类:           txt_ip (d:\documents\visual foxpro 项目\myclass.vcx)
*-- 父类:  textbox
*-- 基类:    textbox
*-- 时间戳:   10/12/25 04:33:07 PM
*
DEFINE CLASS txt_ip AS textbox


    Value = 0.0.0.0
    Height = 20
    Left = 12
    Top = 48
    Width = 110
    Name = "txt_ip"


    PROCEDURE KeyPress
        LPARAMETERS nKeyCode, nShiftAltCtrl
        ndotpos1=AT(".",this.Value,1)
        ndotpos2=AT(".",this.Value,2)
        ndotpos3=AT(".",this.Value,3)
        ncursor=this.SelStart
        *SET MESSAGE TO TRANSFORM(ncursor)
        IF ("." $ this.SelText)
            NODEFAULT && 当选择的字符里有“.”号时，不允许键盘操作
        ELSE 
            DO CASE 
                CASE nkeycode=127
                    IF SUBSTR(this.Value,ncursor,1)="."
                        NODEFAULT 
                    ENDIF 
                CASE nkeycode=7
                    IF SUBSTR(this.Value,ncursor+1,1)="."
                        NODEFAULT 
                    ENDIF 

                CASE nkeycode=9 OR nkeycode=46 OR nkeycode=13
                    IF ncursor<ndotpos3 &&在前三个ip段，改变tab，“.”，回车的默认行为为向后移一个ip段，并全选该段
                        NODEFAULT
                        DO CASE
                            CASE BETWEEN(ncursor,ndotpos2,ndotpos3)

                                this.SelStart=ndotpos3
                                this.SelLength=LEN(this.Value)-ndotpos3-1
                            CASE BETWEEN(ncursor,ndotpos1,ndotpos2)

                                this.SelStart=ndotpos2
                                this.SelLength=ndotpos3-ndotpos2-1
                            CASE BETWEEN(ncursor,0,ndotpos1)

                                this.SelStart=ndotpos1
                                this.SelLength=ndotpos2-ndotpos1-1

                            OTHERWISE

                        ENDCASE
                    ELSE
                        IF nkeycode=46
                            NODEFAULT 
                            KEYBOARD "{tab}" && 在第四个ip段屏蔽“.”以tab键代替
                        ENDIF 
                    ENDIF 

                CASE !(BETWEEN(nkeycode,48,57) OR INLIST(nkeycode,4,7,9,13,19,46,127))
                    NODEFAULT &&只允许数字键和控制键

                OTHERWISE 

            ENDCASE 
        ENDIF      
    ENDPROC


    PROCEDURE GotFocus
        this.SelStart=0
        ndotpos1=AT(".",this.Value)
        this.SelLength=ndotpos1-1

    ENDPROC


    PROCEDURE Valid
        ndots=OCCURS(".",this.Value)
        nsections=ALINES(atemp,this.Value,5,".")
        IF nsections<>4 &&说明有某个段没有输入数字，定位到没有数字的ip段
            this.Selstart=AT("..",this.Value)
            RETURN .f.
        ELSE 
            FOR i=1 TO 4
                IF !BETWEEN(EVALUATE(atemp(i)),0,255) &&ip值有效检查，定位到错误的ip段
                    this.Selstart=IIF(i=1,0,AT(".",this.Value,i-1))
                    this.SelLength=LEN(atemp(i))
                    RETURN .f.
                ENDIF
            ENDFOR 
        ENDIF 


    ENDPROC


ENDDEFINE
*
*-- EndDefine: txt_ip
**************************************************

[此贴子已经被作者于2025-10-12 17:02编辑过]

改天再发表一个电话号码类,只能输入电话号码，感觉挺实用的

10/6 更新代码，valid的判断更加完美，指出哪个值无效；
解决了每个地址端输入3个数字后的块选择问题，定位到错的地址段。

更新后的代码放到一楼了。。。

windows也有个IP地址控件
简单示例

DECLARE long InitCommonControlsEx IN comctl32 string@
DECLARE long CreateWindowExA IN user32 long,string,string,long,long,long,long,long,long,long,long,long

of=CREATEOBJECT("form1")
of.show(1)
CLEAR ALL
RETURN

DEFINE CLASS form1 as Form
    PROCEDURE load
        icex = BINTOC(8,"4rs")+BINTOC(0x0800,"4rs")
        InitCommonControlsEx(@icex)
        CreateWindowExA(0,"SysIPAddress32","",0x50000000,10,10,150,22,this.hWnd,0,0,0)
    ENDPROC
ENDDEFINE

这么简洁？！
居然还有这个控件？可以可视化调用吗？

在keypress中读取或设置selstart属性容易出现不可知的错误，所以代码量比较大且复杂，DS建议不要放在keypress里，那时selstart还没设置，建议放在InteractiveChange方法中，改天试试

[此贴子已经被作者于2025-10-8 07:28编辑过]

这个是windows的标准控件，实际应用中还有一些细节问题要处理，如编辑焦点和插入光标的处理。
MS参考文档：https://learn.

简单的话用vfp的textbox写个IP解析就可以,如：

of=CREATEOBJECT("form1")
of.show(1)

DEFINE CLASS form1 as Form
    ADD OBJECT text1 as text_ip WITH left=10,top=10,width=100,height=20
ENDDEFINE

DEFINE CLASS text_ip as TextBox 
    InputMask = "999.999.999.999"
    PROCEDURE valid
        ALINES(arr,this.Value,".")
        IF BETWEEN(VAL(arr[1]),0,255) AND ;
           BETWEEN(VAL(arr[2]),0,255) AND ;
           BETWEEN(VAL(arr[3]),0,255) AND ;
           BETWEEN(VAL(arr[4]),0,255)
           RETURN .t.
        ENDIF
        ERROR "IP地址输入无效"
        RETURN .f.
    ENDPROC
ENDDEFINE