再次求助：如何将《仙道九绝》各章节内容完整地爬下来？

LOCAL loHtml, lcUrl, lcContent
DECLARE integer Sleep IN WIN32API integer

lcUrl = "http://www./6780946/3664234966.html"
loHtml = CREATEOBJECT("htmlfile")

* 打开HTML文件对象
loHtml.open()

* 创建XMLHTTP请求对象
*loXmlHttp = loHtml.parentwindow.XMLHTTP
loXmlHttp=CREATEOBJECT("WinHttp.WinHttpRequest.5.1")
* 发送GET请求获取内容
loXmlHttp.open("GET", lcUrl, .F.)
loXmlHttp.send("")
=sleep(8000) &&确保下载完成,如果网速慢，适当加长时间。
lcContent = loXmlHttp.responseText

* 将获取的内容写入到HTML文件对象中
loHtml.write(lcContent)

* 关闭HTML文件对象
loHtml.close()
RELEASE loXmlhttp

* 现在可以使用loHtml对象操作文档了
* ? "文档内容:", loHtml.body.innerHTML
* 获得章节内容
lochapter=lohtml.getElementById("chapter")
lcContent=lochapter.innerHTML
lcContent=STRTRAN(lcContent,"<br>","")
lcContent=STRTRAN(lcContent,"&nbsp;","")
*?lcContent
STRTOFILE(lcContent,"wanglaoshi.txt")
*MODIFY FILE wanglaoshi.txt

* 查看分几篇
lapage=ohtml.getElementsByClassName("m-page")
lopage=lapage.item(0)
lcnext=lopage.innerhtml
lcnext=STREXTRACT(lcnext,"<A","</A>",3)
lcnext=JUSTSTEM(lcnext) &&下一章文件名
lccurrent=JUSTSTEM(lcurl) &&当前文件名
IF STREXTRACT(lcnext,"","_")==IIF(EMPTY(STREXTRACT(lccurrent,"","_")),;
    lccurrent,STREXTRACT(lccurrent,"","_"))
   
    MESSAGEBOX("下一页网址："+STRTRAN(lcurl,lccurrent,lcnext))
    *继续爬，代码略。。。
ELSE
    MESSAGEBOX("下一章网址："+STRTRAN(lcurl,lccurrent,lcnext))   
ENDIF
RELEASE lohtml

MODIFY FILE wanglaoshi.txt
* 查看下载的html文件内容
*STRTOFILE(lcContent,"wanglaoshi.html")
*MODIFY FILE wanglaoshi.html

DECLARE long URLDownloadToFileA  IN urlmon  long,string,string,long,long
DECLARE long DeleteUrlCacheEntry IN wininet string
url = "http://www./6780946/3664234966.html"
outFile = "C:\_temp\tmp.html"
dom = CREATEOBJECT("htmlfile")
STRTOFILE(getText(getHtml(url, outFile)), outFile)
MODIFY FILE (outFile)
CLEAR ALL
RETURN

FUNCTION getText(html)
    html = STRCONV(html, 11)
    content = STREXTRACT(html, [rr('], [')])
    TEXT TO jsCode TEXTMERGE NOSHOW PRETEXT 15
        var content = "<<content>>";
        content = window.atob(content);
        var arrays = new Array();   
        arrays = content.split(',');   
        var $chapter = document.getElementById("chapter").innerHTML;   
        document.getElementById("chapter").innerHTML = $chapter.replace(new RegExp(/\[(.*?)\]/), '$1');   
        $chapter = $chapter.replace(new RegExp(/\[.*?\]/), '');   
        var datas = [];   
        datas = $chapter.split('<br><br>');   
        var $html = '';   
        var el = arrays[0];   
        var len = datas.length;   
        for (var i = 1; i <= len; i++) {        
            $html += datas[arrays[i] - el] + '<br/><br/>';   
        }   
        document.getElementById("ad").innerHTML = $html;   
    ENDTEXT
    html = STRTRAN(html, "<script", "<soript")
    dom.write(html)
    dom.parentWindow.execScript(jsCode)
    content = dom.getElementById("ad").innerTEXT
    dom.close
    RETURN content
ENDFUNC

FUNCTION getHtml(url, outFile)
    IF URLDownloadToFileA(0, url, outFile, 0, 0)==0
        DeleteUrlCacheEntry(url)
        RETURN FILETOSTR(outFile)
    ENDIF
    RETURN ""
ENDFUNC

** 从第一章开始
cUrl = "http://www./6780946/3664234966.html"
http = CREATEOBJECT("WinHttp.WinHttpRequest.5.1")
html = CREATEOBJECT("htmlfile")
html.designmode = "on"
html.write(".")
outFile = "C:\_temp\仙道九绝.dbf"
CREATE TABLE (outFile) (标题 V(50), 网址 V(50), 内容 M)
getHtmlText(cUrl)
SELECT * FROM 仙道九绝
CLOSE TABLES ALL
CLEAR ALL
RETURN

FUNCTION getHtmlText(cUrl)
    PRIVATE cHtml, host, purl, chapters, title, pages, n, m
    cHtml = ""
    host  = "http://" + STREXTRACT(cUrl, "http://", "/")
    purl  = host+"/6780946/"
    pages = getPages(purl)
    IF pages == 0
        RETURN
    ENDIF
    chapters = ""
    chapterUrl = cUrl
    title = ""
    wait = CREATEOBJECT("wait_form")
    wait.show
    n = 1                            && 章节计数
    m = wait.statbox.width / pages   && 进度条单位
    DO WHILE !(cUrl==purl) AND getHtmlTextByUrl(cUrl,@cHtml)
        cUrl = getChapter(cHtml, cUrl)
        #if 0    && 调试用
        IF n>10
            exit
        ENDIF
        #endif
    ENDDO
    wait.release
ENDFUNC

FUNCTION getChapter(cHtml, cUrl)
    html.getElementsByTagName("body").item[0].innerHTML = cHtml
    LOCAL chapter, content
    title   = STREXTRACT(html.getElementsByTagName("title").item[0].innerText, "_", "_")
    chapter = html.getElementById("chapter").innerText
    chapter = STRTRAN(chapter, STREXTRACT(chapter, "[","]",1,4), "")
    content = STRCONV(ALLTRIM(html.getElementById("ad").innerText, "_ii_rr('", "');"), 14)
    ALINES(arrays, content, 5, ",")
    lines = ALINES(aDatas, chapter, 0h0D0A0D0A)
    code1 = VAL(arrays[1])
    chapter = ""
    FOR i=2 TO lines+1    && 取一页
        chapter = chapter + aDatas[VAL(arrays[i]) - code1 + 1] + 0h0D0A0D0A
    ENDFOR
    chapters = chapters + RTRIM(chapter,0h0D0A)    && 每章各页
    page = html.getElementsByClassName("m-tpage").item[0].getElementsByTagName("a").item[2].getAttribute("href")
    IF !(LEFT(page,AT("_",page)-1) $ cUrl)
        INSERT INTO 仙道九绝 VALUES (title, chapterUrl, chapters)
        chapters = ""
        chapterUrl = host + page  && 下一章
        wait.msg.caption = title+0h0D0D+chapterUrl
        wait.statbar.width = m * n
        n = n+1
    ENDIF
    RETURN host + page    && 下一页
ENDFUNC

FUNCTION getHtmlBodyByUrl(cUrl, pHtml)
    RETURN getHtmlByUrl(cUrl, @pHtml, 0)
ENDFUNC

FUNCTION getHtmlTextByUrl(cUrl, pHtml)
    RETURN getHtmlByUrl(cUrl, @pHtml, 1)
ENDFUNC

FUNCTION getHtmlByUrl(cUrl, pHtml, nFlags)
  TRY
    pHtml = ""
    LOCAL err
    err = .f.
    http.open("GET", cUrl, 0)
    http.send()
    IF http.status == 200
        IF nFlags == 0
            pHtml = http.ResponseBody
        ELSE
            pHtml = http.ResponseText
        ENDIF
    ENDIF
  CATCH
    err = .t.      
  ENDTRY
    IF err
        MESSAGEBOX("获取网页失败"+0h0D+cUrl)  
    ENDIF
    RETURN !err
ENDFUNC

FUNCTION getPages(purl)
    LOCAL pHtml
    IF getHtmlTextByUrl(purl, @pHtml)
        html.getElementsByTagName("body").item[0].innerHTML = pHtml
        RETURN VAL(STREXTRACT(html.getElementById("play_0").getElementsByTagName("li").item[0].innerText,"第","章"))
    ENDIF
    RETURN 0
ENDFUNC

DEFINE CLASS wait_form as Form
    width = 500
    height = 150
    AutoCenter = .t.
    showwindow = 0
    windowtype = 0
    titlebar = 0
    movable = .f.
    borderstyle = 2
    alwaysontop = .t.
    ADD OBJECT msg as label WITH left=20,top=20,width=460,height=60,;
        caption="请稍候......",alignment=2,fontsize=12
    ADD OBJECT statbox as shape WITH left=20,top=100,width=460,height=22,;
        SpecialEffect=1,BackColor=0x00FFFFFF,BorderColor=0x00C0C0C0
    ADD OBJECT statbar as shape WITH left=20,top=100,width=0,height=22,;
        SpecialEffect=1,BackColor=0x00C08000,BorderColor=0x00C0C0C0
    PROCEDURE DblClick
        this.Release
    ENDPROC
ENDDEFINE

function _ii_rr(content) {
    content = window.atob(content);
    var arrays = new Array();
    arrays = content.split(',');
    var $chapter = document.getElementById("chapter").innerHTML;
    console.log($chapter);
    document.getElementById("chapter").innerHTML = $chapter.replace(new RegExp(/\[(.*?)\]/), '$1');
    $chapter = $chapter.replace(new RegExp(/\[.*?\]/), '');
    var datas = [];
    datas = $chapter.split('<br><br>');
    var $html = '';
    var el = arrays[0];
    var len = datas.length;
    for (var i = 1; i <= len; i++) {
        $html += datas[arrays[i] - el] + '<br/><br/>';
    }
    document.getElementById("ad").innerHTML = $html;
    document.getElementById('chapter').style.color = '#FBF6EC';
    document.getElementById("chapter").style.height = "5px";
    document.getElementById('chapter').style.display = 'none';
}

** 测试用 JS 代码，参考 http://www./js/zepto.js 修改。
** 模拟写 JS 文件，实际应用通常先写好 JS 文件。
TEXT TO jsCode TEXTMERGE NOSHOW PRETEXT 15
    <script>
    var content = document.getElementById("ad").innerText;
    eval(content);

    function _ii_rr(content) {   
        content = window.atob(content);   
        var arrays = new Array();   
        arrays = content.split(',');   
        var $chapter = document.getElementById("chapter").innerHTML;   
        $chapter = $chapter.replace(new RegExp(/\[.*?\]/), '');   
        var datas = [];   
        datas = $chapter.split('<br><br>');   
        var $html = '';   
        var el = arrays[0];   
        var len = datas.length;   
        for (var i = 1; i <= len; i++) {        
            $html += datas[arrays[i] - el] + '<br/><br/>';   
        }   
        document.getElementById("ad").innerHTML = $html;
    }
    </script>
ENDTEXT
jsFile = "C:\_temp\jscode.js"
STRTOFILE(jsCode, jsFile)
** 模拟写 JS 文件结束

** 爬代码
cUrl = "http://www./6780946/3664234966.html"
http = CREATEOBJECT("WinHttp.WinHttpRequest.5.1")
http.open("GET", cUrl, 0)
http.send()
IF http.status != 200
    RETURN
ENDIF
dom = CREATEOBJECT("htmlfile")
dom.write(STRTRAN(http.ResponseText, "script", "soript"))
dom.writeln(FILETOSTR(jsFile))
outFile = "C:\_temp\tmp.txt"
STRTOFILE(dom.getElementById("ad").innerText, outFile)
MODIFY FILE (outFile)
CLEAR ALL
RETURN