注册 登录
编程论坛 → VFP论坛

实用的一个文本框类，只能输入ip地址

sam_jiang 发布于 2025-10-06 00:50， 474 次点击
如题。欢迎暴力测试，找出bug！

10/12再次更新代码如下：
解决selstart值不正确的问题
弃用inputmask，它限制了输入格式

程序代码：

**************************************************
*-- 类:           txt_ip (d:\documents\visual foxpro 项目\myclass.vcx)
*-- 父类:  textbox
*-- 基类:    textbox
*-- 时间戳:   10/12/25 04:33:07 PM
*
DEFINE CLASS txt_ip AS textbox


    Value = 0.0.0.0
    Height = 20
    Left = 12
    Top = 48
    Width = 110
    Name = "txt_ip"


    PROCEDURE KeyPress
        LPARAMETERS nKeyCode, nShiftAltCtrl
        ndotpos1=AT(".",this.Value,1)
        ndotpos2=AT(".",this.Value,2)
        ndotpos3=AT(".",this.Value,3)
        ncursor=this.SelStart
        *SET MESSAGE TO TRANSFORM(ncursor)
        IF ("." $ this.SelText)
            NODEFAULT && 当选择的字符里有“.”号时，不允许键盘操作
        ELSE
            DO CASE
                CASE nkeycode=127
                    IF SUBSTR(this.Value,ncursor,1)="."
                        NODEFAULT
                    ENDIF
                CASE nkeycode=7
                    IF SUBSTR(this.Value,ncursor+1,1)="."
                        NODEFAULT
                    ENDIF

                CASE nkeycode=9 OR nkeycode=46 OR nkeycode=13
                    IF ncursor<ndotpos3 &&在前三个ip段，改变tab，“.”，回车的默认行为为向后移一个ip段，并全选该段
                        NODEFAULT
                        DO CASE
                            CASE BETWEEN(ncursor,ndotpos2,ndotpos3)

                                this.SelStart=ndotpos3
                                this.SelLength=LEN(this.Value)-ndotpos3-1
                            CASE BETWEEN(ncursor,ndotpos1,ndotpos2)

                                this.SelStart=ndotpos2
                                this.SelLength=ndotpos3-ndotpos2-1
                            CASE BETWEEN(ncursor,0,ndotpos1)

                                this.SelStart=ndotpos1
                                this.SelLength=ndotpos2-ndotpos1-1

                            OTHERWISE

                        ENDCASE
                    ELSE
                        IF nkeycode=46
                            NODEFAULT
                            KEYBOARD "{tab}" && 在第四个ip段屏蔽“.”以tab键代替
                        ENDIF
                    ENDIF

                CASE !(BETWEEN(nkeycode,48,57) OR INLIST(nkeycode,4,7,9,13,19,46,127))
                    NODEFAULT &&只允许数字键和控制键

                OTHERWISE

            ENDCASE
        ENDIF      
    ENDPROC


    PROCEDURE GotFocus
        this.SelStart=0
        ndotpos1=AT(".",this.Value)
        this.SelLength=ndotpos1-1

    ENDPROC


    PROCEDURE Valid
        ndots=OCCURS(".",this.Value)
        nsections=ALINES(atemp,this.Value,5,".")
        IF nsections<>4 &&说明有某个段没有输入数字，定位到没有数字的ip段
            this.Selstart=AT("..",this.Value)
            RETURN .f.
        ELSE
            FOR i=1 TO 4
                IF !BETWEEN(EVALUATE(atemp(i)),0,255) &&ip值有效检查，定位到错误的ip段
                    this.Selstart=IIF(i=1,0,AT(".",this.Value,i-1))
                    this.SelLength=LEN(atemp(i))
                    RETURN .f.
                ENDIF
            ENDFOR
        ENDIF


    ENDPROC


ENDDEFINE
*
*-- EndDefine: txt_ip
**************************************************



[此贴子已经被作者于2025-10-12 17:02编辑过]

15 回复
#2
schtg2025-10-06 05:39
#3
sam_jiang2025-10-06 07:15
改天再发表一个电话号码类,只能输入电话号码，感觉挺实用的
#4
laowan0012025-10-06 07:15
#5
sam_jiang2025-10-06 21:25
10/6 更新代码，valid的判断更加完美，指出哪个值无效；
解决了每个地址端输入3个数字后的块选择问题，定位到错的地址段。

更新后的代码放到一楼了。。。
#6
吹水佬2025-10-07 23:19
windows也有个IP地址控件
简单示例
只有本站会员才能查看附件，请 登录

程序代码：

DECLARE long InitCommonControlsEx IN comctl32 string@
DECLARE long CreateWindowExA IN user32 long,string,string,long,long,long,long,long,long,long,long,long

of=CREATEOBJECT("form1")
of.show(1)
CLEAR ALL
RETURN

DEFINE CLASS form1 as Form
    PROCEDURE load
        icex = BINTOC(8,"4rs")+BINTOC(0x0800,"4rs")
        InitCommonControlsEx(@icex)
        CreateWindowExA(0,"SysIPAddress32","",0x50000000,10,10,150,22,this.hWnd,0,0,0)
    ENDPROC
ENDDEFINE
#7
schtg2025-10-08 06:28
#8
sam_jiang2025-10-08 07:09
这么简洁？！
居然还有这个控件？可以可视化调用吗？

在keypress中读取或设置selstart属性容易出现不可知的错误，所以代码量比较大且复杂，DS建议不要放在keypress里，那时selstart还没设置，建议放在InteractiveChange方法中，改天试试

[此贴子已经被作者于2025-10-8 07:28编辑过]
#9
吹水佬2025-10-08 07:30
以下是引用sam_jiang在2025-10-8 07:09:57的发言：

这么简洁？！
居然还有这个控件？可以可视化调用吗？

这个是windows的标准控件，实际应用中还有一些细节问题要处理，如编辑焦点和插入光标的处理。
MS参考文档：https://learn.
#10
吹水佬2025-10-08 08:03
简单的话用vfp的textbox写个IP解析就可以,如：
程序代码：

of=CREATEOBJECT("form1")
of.show(1)

DEFINE CLASS form1 as Form
    ADD OBJECT text1 as text_ip WITH left=10,top=10,width=100,height=20
ENDDEFINE

DEFINE CLASS text_ip as TextBox
    InputMask = "999.999.999.999"
    PROCEDURE valid
        ALINES(arr,this.Value,".")
        IF BETWEEN(VAL(arr[1]),0,255) AND ;
           BETWEEN(VAL(arr[2]),0,255) AND ;
           BETWEEN(VAL(arr[3]),0,255) AND ;
           BETWEEN(VAL(arr[4]),0,255)
           RETURN .t.
        ENDIF
        ERROR "IP地址输入无效"
        RETURN .f.
    ENDPROC
ENDDEFINE
#11
吹水佬2025-10-08 09:00
也可以模拟 Internet 协议的IP格式由四个三位数字段组成，每个字段单独处理。
实际应用中通常是用 in_addr 结构表示IP地址。
in_addr结构简单可以这样理解：
struct in_addr {
    u_char s_b1;
    u_char s_b2;
    u_char s_b3;
    u_char s_b4;
};

只有本站会员才能查看附件，请 登录

程序代码：

of=CREATEOBJECT("form1")
of.show(1)

DEFINE CLASS form1 as Form
    ADD OBJECT label1 as label WITH left=10,top=10,width=135,height=16,backcolor=0x00FFFFFF,;
        BorderStyle=1,caption="     .     .     .     "
    ADD OBJECT ip1 as text_ip WITH left=11,top=11,width=30,height=14
    ADD OBJECT ip2 as text_ip WITH left=42,top=11,width=30,height=14
    ADD OBJECT ip3 as text_ip WITH left=78,top=11,width=30,height=14
    ADD OBJECT ip4 as text_ip WITH left=114,top=11,width=30,height=14
ENDDEFINE

DEFINE CLASS text_ip as TextBox
    Alignment = 2
    BorderStyle = 0
    Margin = 0
    Format = "Z"
    InputMask = "999"
    value = 0
    PROCEDURE valid
        RETURN BETWEEN(this.Value,0,255)
    ENDPROC
ENDDEFINE
#12
foxfans2025-10-08 14:15
可以进一步完成兼容ipv4与6,下面是验证地址有效性（只判断）
CLEAR
DECLARE INTEGER inet_pton IN ws2_32.dll INTEGER af, STRING src, STRING @dst

cIPv4Addr = SPACE(4)
cInput = "192.168.1.1"
nResult = inet_pton(2, cInput, @cIPv4Addr)
IF nResult = 1 THEN
  ? "IPv4地址有效"
ELSE
  ? "IPv4地址无效"
ENDIF

cIPv6Addr = SPACE(16)
cInput = "2001:1db8:35a3:ff00:0130:8a2e:0370:7334"
nResult = inet_pton(23, cInput, @cIPv6Addr)
IF nResult = 1 THEN
  ? "IPv6地址有效"
ELSE
  ? "IPv6地址无效"
ENDIF
*!*    CLEAR DLLS "inet_pton"
#13
sam_jiang2025-10-08 17:37
回复 11楼 吹水佬
ds也是建议用container+textbox+label来解决
#14
sam_jiang2025-10-12 16:59
重新思考了一下ipaddress控件的逻辑，总算避坑了，完美解决。代码更新在1楼，赶快下载运用去吧。

让ds给我评价一下，好像评价不错。

下次更新，考虑ipv6。。。

[此贴子已经被作者于2025-10-12 18:12编辑过]
#15
sych2025-10-13 08:20
回复 12楼 foxfans
这个很实用，谢谢
#16
hsfisher2025-10-13 08:33
1
©2025, BC-CN.NET
电脑版