如何实现vb 模拟鼠标点击其他应用程序内的命令按键

不知道怎么弄，您能说的再详细点不，有没有参考代码给我参考下，谢谢！

网上都说按我上面的代码就能实现，为什么我测试就只能再VB的应用内实现，离开VB到其他应用就不行。

我大概明白你的意思了，你是说用按键精灵录制，就可以间接得到VB源码，然后再植入到我的工程里，是这样吗？谢谢！

如果你要用到串口，那就没办法用按键精灵了。那就老老实实用VB6了。

无法实现点击，要查 API 函数说明。

SetCursorPos是设置光标而不是鼠标。
使用mouse_event 移动鼠标到指定位置。
以下代码供参考：
Private Declare Sub mouse_event Lib "user32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
Private Const MOUSEEVENTF_LEFTDOWN = &H2
Private Const MOUSEEVENTF_LEFTUP = &H4
Private Const MOUSEEVENTF_MOVE =1 '移动鼠标标志
Private Const MOUSEEVENTF_ABSOLUTE =32768 '使用绝对坐标
Private sub command1
mouse_event MOUSEEVENTF_ABSOLUTE or MOUSEEVENTF_MOVE ,Val(Text1.Text), Val(Text2.Text),0,0

mouse_event MOUSEEVENTF_LEFTDOWN or MOUSEEVENTF_LEFTUP , 0, 0, 0, 0

end sub
Private sub command2
msgbox"模拟鼠标按键"
end sub

1、可以获取屏幕鼠标位置
2、可以点击设置位置的鼠标
3、源程序

Private Declare Function SetCursorPos Lib "user32" (ByVal x As Long, ByVal y As Long) As Long
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Sub mouse_event Lib "user32" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)
Private Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer
Const MOUSEEVENTF_LEFTDOWN = &H2
Const MOUSEEVENTF_LEFTUP = &H4
Private Type POINTAPI
 x As Long
 y As Long
End Type

'启动获得坐标定时器
Private Sub Command1_Click()
  If Command1.Caption = "获取屏幕坐标" Then
    Timer1.Interval = 200
    Command1.Caption = "F12停止获取"
  End If
End Sub
'设置鼠标位置并点击
Private Sub Command2_Click()
  SetCursorPos Val(Text1.Text), Val(Text2.Text)                      '设置鼠标位置
  mouse_event MOUSEEVENTF_LEFTDOWN Or MOUSEEVENTF_LEFTUP, 0, 0, 0, 0 '点击坐标位置鼠标
  DoEvents
End Sub
'获得鼠标位置和键盘输入
Private Sub Timer1_Timer()
  Dim P As POINTAPI
  GetCursorPos P    '取的鼠标位置
  Text1.Text = P.x
  Text2.Text = P.y
  KeyResult = GetAsyncKeyState(123) '取的F12
  If KeyResult = -32767 Then
    Timer1.Interval = 0
    Command1.Caption = "获取屏幕坐标"
  End If
End Sub

不需要坐标，通过遍历第三方程序的控件句柄，直接向控件句柄发送单击或双击消息，即可完成单击或双击。

下面代码通过第三方程序的句柄，遍历其中包含的控件句柄。

API操作其他程序中的按钮
https://blog.

ToolBar控件有句柄，但里面有子按钮，子按钮没找到句柄

如果找到Toolbar 子按钮的ID是否可以操作它？

您正在谈论的控件正在使用ToolbarWindow32类。如果要与他们互动，则需要使用工具栏控件的API /消息。例如，要启用按钮，您想使用TB_ENABLEBUTTON。  

可能是绘制的按钮，不是控件，所以没有句柄。

网上很多，但代码无法正常运行。百度搜索：VB ToolbarWindow32     看一下。

获得 button ID，然后发 wm_command,不就行了。
wparam 的低字指定buttonId,高字为0，
lparam 指定toolbar句柄，
你上面的代码，已经可以获得id，应该不难吧。

按照你说的方法已经测试好了，经测试发现对于类型为：ToolbarWindow32的可以有效，但针对VB ToolBar控件类型 msvb_lib_toolbar 无效，但可以变更按钮状态，不知为何。

不会吧？你试以下代码

Option Explicit
Private Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hWnd As Long, lpdwProcessId As Long) As Long
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcId As Long) As Long
Private Declare Function ReadProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Long, ByRef lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Const PROCESS_VM_OPERATION = &H8
Private Const PROCESS_VM_READ = &H10
Private Declare Function VirtualAllocEx Lib "kernel32" (ByVal hProcess As Long, ByVal lpAddress As Long, ByVal dwSize As Long, ByVal flAllocationType As Long, ByVal flProtect As Long) As Long
Private Const MEM_COMMIT = &H1000
Private Const PAGE_READWRITE = &H4
Private Const MEM_RELEASE = &H8000&
Private Declare Function VirtualFreeEx Lib "kernel32" (ByVal hProcess As Long, ByVal lpAddress As Long, ByVal dwSize As Long, ByVal dwFreeType As Long) As Long

Private Declare Function GetParent Lib "user32" (ByVal hWnd As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Const WM_COMMAND = &H111

Private Type TBBUTTON
   iBitmap      As Long
   idCommand    As Long
   fsState      As Byte
   fsStyle      As Byte
   bReserved1   As Byte
   bReserved2   As Byte
   dwData       As Long
   iString      As Long
End Type
Private Const TB_GETBUTTON = &H417

Private Sub Command1_Click()
    Dim hWnd As Long, Index As Long
   
    hWnd = 指定 toolbar 句柄
    Index = 指定 toolbar 索引，范围 = 0 ～ 按钮总数-1
    Call GotoButtonClick(hWnd, Index)
End Sub

Private Sub GotoButtonClick(ByVal hWnd As Long, ByVal Index As Long)
'hWnd      toolbar 句柄；
'Index     toolbar 索引，范围 = 0 ～ 按钮总数-1；
    Dim hParent As Long, ButtonID As Long
  
    hParent = GetParent(hWnd)
    ButtonID = GetButtonID(hWnd, Index)
    Call PostMessage(hParent, WM_COMMAND, ButtonID, ByVal hWnd)
End Sub

Private Function GetButtonID(ByVal hWnd As Long, ByVal Index As Long) As Long
    Dim ProcesshWnd As Long, ProcessId As Long, Buffer As Long, Len1 As Long
    Dim iButton     As TBBUTTON
   
    Len1 = LenB(iButton)
    Call GetWindowThreadProcessId(hWnd, ProcessId)
    ProcesshWnd = OpenProcess(PROCESS_VM_OPERATION Or PROCESS_VM_READ, 0, ProcessId)
    Buffer = VirtualAllocEx(ProcesshWnd, 0, Len1, MEM_COMMIT, PAGE_READWRITE)
   
    Call SendMessage(hWnd, TB_GETBUTTON, Index, ByVal Buffer)
    Call ReadProcessMemory(ProcesshWnd, Buffer, iButton, Len1, 0)
   
    GetButtonID = iButton.idCommand
    Call VirtualFreeEx(ProcesshWnd, Buffer, 0, MEM_RELEASE)
    Call CloseHandle(ProcesshWnd)
End Function

1.SendClick = PostMessage(Hwnd_JY, WM_COMMAND, lButtonID, 0) 'PostMessage(主窗口句柄, WM_COMMAND, 控件ID号, 0) 此种写法也是成功的,Hwnd_JY是主窗口句柄;
2.此种方式类似于发送菜单ID的方式,经测试没有问题
3.Foxmail软件百度随便可以下载安装,TTBXToolbar 类有可能是它自己的,搞不明白,不是toolBarWindows32的类 不会起作用的