关于树形菜单，如何简化菜单代码，在数据表中进行菜单设置，点击节点打开相应的窗体？ - 编程论坛

#2

hmj07452021-12-15 16:41

我前天说的哪个思路，如果把菜单节点名称设置成和窗体名称一致，我刚试了一下，是可以直接打开的，给你参考下。
Private Sub CDTree_NodeClick(ByVal Node As MSComctlLib.Node)
Dim FrmName As String, TmpForm As Form
FrmName = Node.Text '//把节点名称赋值给FrmName
Set TmpForm = Forms.Add(FrmName)
TmpForm.Show 0
end sub

#3

wlbwxd2021-12-15 19:58

回复 2楼 hmj0745

非常感谢hmj0745的支持！
我测试了一下OK,达到预期效果。
另外，节点名称赋值给FrmName ,这里改了一下，使用Key作为FrmName，因为程序中窗体是英文名，与节点Node.Text不一致
修改后源码如下：
Private Sub TreeView1_NodeClick(ByVal Node As MSComctlLib.Node)
    On Error GoTo 111
    Dim FrmName As String, TmpForm As Form
    TreeView1.SingleSel = True
    FrmName = Node.Key '//把节点名称赋值给FrmName
    Set TmpForm = Forms.Add(FrmName)
    TmpForm.Show 0
111:
    Exit Sub
End Sub

#4

风吹过b2021-12-15 20:07

我也想也一个思路，写了一个示例，使用 listbox 来展示的，其它差不多原理。

其实窗体不应该使用 name 或 Caption ，这二个是有可能有重命的，而应该使用 hwnd 来标识每一个窗体。

只有本站会员才能查看附件，请登录

#5

hmj07452021-12-15 20:43

回复 4楼风吹过b

的确，句柄的唯一性，更精准。
我看风版这个示例来做一个产品图纸查看器，很不错。
把子窗体和MDI窗体的缩放同步做一致，或是再增加一个并列对比模式。
x,y 方向加上滚动条，按下鼠标移动时，让滚动条的value 值相应变化。可以产生移动图纸效果。
如果滚轮能给局部放大，像CAD里一样，就更好了。这个后面要试一下。

#6

风吹过b2021-12-16 19:24

后面想到了，不用这么麻烦针对窗体上每个控件都写一行代码，可以用定时器来扫描窗体情况。
这种的法，子窗体不需要添加任何代码，每次窗体发生变化后，定时扫描窗体情况，然后进行添加、减少，修改活动窗体。

在 mdi窗体上，放一个定时器，Interval 属性设 100 ,感觉差不多了。
list2的 Style 要设为 1-VbListBoxCheckbox 或者 MultiSelect 属性设 1 或 2 。

代码

程序代码：

Private Sub Timer1_Timer()
Static AFhWnd As Long     '上一次扫描时活动窗体 hWnd
Static FrmCount As Long   '上一次扫描时总窗体数
Dim frm As Form, i As Long

If Forms.Count > 1 Then         '如果当前窗体数量>1
    '如果保存的活动窗体没有发生变化并且总窗体数也没变化时不处理
    If Me.ActiveForm.hWnd = AFhWnd And FrmCount = Forms.Count Then Exit Sub
Else
    Exit Sub
End If
FrmCount = Forms.Count

Debug.Print AFhWnd, FrmCount

'清list2中的选择
    For i = 0 To List2.ListCount - 1
        List2.Selected(i) = False
    Next i

'遍类所有的窗体
For Each frm In Forms
    If Not frm Is Me Then           '不是mdi窗体，本过程是写在 MDI窗体代码中
        For i = 0 To List2.ListCount - 1
            If List2.List(i) = frm.hWnd Then
                List2.Selected(i) = True
                Exit For
            End If
        Next i

        '未找到，则添加
        If i > List2.ListCount - 1 Then
            List1.AddItem frm.Caption
            List2.AddItem frm.hWnd
            List2.Selected(i) = True
        End If
    End If
    If frm Is Me.ActiveForm Then
        GotFocusYN = True
        List1.ListIndex = i
        AFhWnd = frm.hWnd
        GotFocusYN = False
    End If
Next

'清已经关闭的窗体记录
    For i = List2.ListCount - 1 To 0 Step -1
        If Not List2.Selected(i) Then
            List1.RemoveItem i
            List2.RemoveItem i
        End If
    Next i

End Sub