用删除法编写一个制作素数表的vfp程序

所用素数表和数据源表：

有人浏览了，没有进行提问，也不知道是否理解问题？有不清楚的地方，我希望大家问出来，我好针对的回答。就是二层循环，外层循环就是成批的调入数据，内循环是主角，虽然没有按网上的把记录条标记真与假，用求余数法去掉了被筛除数，道理是一样的，对于内循环次数也容易获得。不知大家怎么看？

语文水平有限，不知道你说什么，你要做什么。。。

就是用划掉法制作素数表。用筛选法制作素数表，是每调入一个正整数，把它开方值以前的素数都用一遍，中间时，有整除的直接跳出循环，然后筛选下一个值。
而此种方法就是一下子调入一批数（假如100个正整数或者1千个，甚至更多），求出此批次最大一个值的开方数，找到开方值以前的所有素数（即素数≤根号n（n是这批次的最大值）），确定最后一个符合条件的素数所在的记录条，以此记录条作为内循环值（循环次数），因为数据源是经过素数2至19处理的，所以不在做检验，直接从第9个素数23开始，进入内循环即可，所以内循环次数-8，在内循环中有两个表，目的是盛方待处理数据，每次外循环进入前，先把数据调入数据a表，然后调入第一个条件素数23，进行筛选，把23的倍数去掉后，剩下的被筛选数据放到数据b表中，调入下一个素数29，筛选数据b表中的数，把被29整除的去掉，剩下存放在数据a表中（当然存前需要清空数据，在第一步时一样，先清空数据b表），数据a与数据b来回互换，当筛选完后，判断筛选次数是奇数还是偶数，根据奇偶性，可以判断出那个表中的数据为最终结果，然后把结果抄写到素数表结果中即可，完成本次外循环，进入下一个外循环值，进行同样步骤。
如果还是不理解，可以针对性提问。
说起语文水平，我更是一般，只能是中下水平，语言表达，也是不到位，无法准确无误表达我的想法和思路，沟通起来有点费劲。

1.向大家介绍这个问题的解决思路
2.问大家你的解决思路是否可行
3.需要有人帮忙用程序实现你的解决方法
4.其他
不知楼主的意思是哪个

把1至3连起来就是我的意思。

按你上面的程序执行后，最后的结果表的记录数是276480条吗？

[此贴子已经被作者于2021-9-14 15:00编辑过]

这是程序的最后一段计算数据，整个程序是从1开始的，那只运算了2个外循环，一次外循环可以处理510510自然数段内的92160个数值。运算结果不对。

那个数是需要处理的用数，里边有多少个素数找出来就可以了。不过，本问题不要用此程序，基本效仿把数排成一行或一列，然从素数3开始，划去其倍数，（奇数等差数列，不含1）,继续划去5得倍数，一直这样划下去，直到最后一个素数倍划完为止，当然这个最后素数是本组数中最大的那个开方值前的最大素数。

先整好一个存放素数DBF，用时查表

嗯，好长

关键是要用素数表，必须提前制作。就是用主题中的方法来制作素数表（我发了另一种制作素数表的程序，太慢了，无法满足要求）。

是这种方式与处理结果。只不过这种没有分段，如果一次性处理一亿个数据，数组的长度有没有限制，即是没有限制，加大到10亿的数据量如何？最关键的是可能还大。所以必须改变一下，每次只处理一个固定周期内的数据，我给的数据源是9699690为周期的，里边有1658880个数据等待处理（一次性处理，不是一个一个的处理），每循环一个外循环值，数据源中的值加一个周期数9699690，进入第二个外循环，最里层的循环用mod(n,p)是否为0作为筛选条件（与其加它本身是一会事儿），在这个过程中，如果有被整除的就去掉了，不在进入下一个素数的排查之内。把最后一个待检验素数执行以后，判断最内层循环次数的奇偶性，找出那个是最终结果（数据a与数据b选其一，当然是正确的那个），把结果抄写到盛方素数的表中，此次外循环一次的数据处理完毕，进入第二轮即可。

反正是用DBF来存放，直接用DBF代替数组好了，DBF的记录号就当是数组的下标，但DBF也是有限。

CLEAR
SELECT 1
USE D:\标记法\数据源表.DBF ALIAS 数据源
SELECT 2
USE D:\标记法\素数表5万.DBF ALIAS 素数表参
SELECT 3
USE D:\标记法\数据表a.DBF ALIAS 数据a
SELECT 4
USE D:\标记法\数据表b.DBF ALIAS 数据b
SELECT 5
USE D:\标记法\素数表结果.DBF ALIAS 素数表果
                                  && bcz=510510  
kssj=SECONDS()                     
FOR i=1 TO 2
@12,10 SAY i
   SELECT 3
   DELETE ALL &&因为此表将写入新的数据，所以提前清空数据，即记录条值
   PACK
   SELECT 1
   GO 1
   FOR j=1 TO 1658880
   sss=素数式
   dclz=sss+(i-1)*9699690  &&dclz是待处理值
   SELECT 3
   APPEND BLANK
   REPLACE 数据1 WITH dclz
   SELECT 1
   SKIP
   ENDFOR
      SELECT 3
      GO 1658880
      bpz=数据1
      Kf=INT(SQRT(bpz))
      GO 1
      SELECT 2
      GO 1
      COUNT ALL FOR 素参<=kf TO jlh  && jlh=RECNO()
      xhcs=jlh-8 &&xhcs是循环次数的简写（第一个字母代替）
      SELECT 2   
      GO 9
      FOR k=1 TO xhcs
       sc=素参
        IF  MOD(k,2)=1
          SELECT 4
          DELETE ALL
          PACK
          SELECT 3
          jlts1=RECCOUNT()  &&把数据a表中的记录条总数赋给变量：jlts1
          GO 1
            for h1=1  to jlts1
            sj1=数据1
            ys1=MOD(sj1,sc)
            IF ys1=0
            ELSE
            SELECT 4
            APPEND BLANK
            REPLACE 数据2 WITH sj1
            ENDIF
            SELECT 3
            SKIP
            ENDFOR
         ELSE
           SELECT 3
           DELETE ALL
           PACK
           SELECT 4
           jlts2=RECCOUNT()  &&把数据b表中的记录条总数赋给变量：jlts2
            GO 1
            for h2=1  to jlts2
            sj2=数据2
            ys2=MOD(sj2,sc)
            IF ys2=0
            ELSE
            SELECT 3
            APPEND BLANK
            REPLACE 数据1 WITH sj2
            ENDIF
            SELECT 4
            SKIP
            ENDFOR
          ENDIF
       SELECT 2
       skip  
       ENDFOR
          IF MOD(xhcs,2)=1
          SELECT 4
          jlts3=RECCOUNT()
          GO 1
          for h3=1  to jlts3
           sj3=数据2
           SELECT 5
           APPEND BLANK
           REPLACE 素数 WITH sj3
           SELECT 4
           SKIP
          ENDFOR
          ELSE
          SELECT 3
          jlts4=RECCOUNT()
          GO 1
          for h4=1  to jlts4
           sj4=数据1
           SELECT 5
           APPEND BLANK
           REPLACE 素数 WITH sj4
           SELECT 3
           SKIP
          ENDFOR
          ENDIF
 ENDFOR
 =MESSAGEBOX("运行时间："+LTRIM(STR(INT((SECONDS()-kssj)/60)))+"分"+LTRIM(STR(MOD(SECONDS()-kssj,60),5,2))+"秒",64,"运行时间提示")
这是我编写的程序，能正常运行，两周的运算时间为：29分40.24秒，在素数表结果中存储了1234399个数据，第一个1不是素数，第二个素数从3119开始的，3119前有443个素数，由1234399-1+443=1234841个素数，与以前方法制作的素数表中2*9699690=19399380内的素数个数一致，说明算法正确。
还是不满意运行时间，仍就偏大，不知道以前的方法运行时间是多少了（有空运行后再比对）。

CLEAR
SELECT 1
USE D:\vfp温习\素数式至19表.DBF ALIAS 素数式表
SELECT 2
USE D:\vfp温习\素数表万3.DBF ALIAS 素数表万3
SELECT 3
USE D:\vfp温习\素数表实验.DBF ALIAS 素数表 &&当时仅改变了别名，没有改原名，在素数表亿新后增加了198-200周期素数，改正，并去掉了后续素数
*INPUT "请输入预先值 K= " TO yxk
*INPUT "请输入步长值 bcz= " TO bcz
*INPUT "请输入初始值 csz= " TO csz
*INPUT "请输入外循环起始值 xks= " TO xks
*INPUT "请输入外循环终结值 zds= " TO zds
bcz=9699690 &&从2乘到17，即素数17的素数阶乘
kssj=SECONDS()                      &&取出开始时间
FOR i=1 TO 2
@12,10 SAY i
            &&调了下顺序，原来在FOR j=1 TO 92160 的下边，执行第一个外循环，提示已经到了表尾
FOR j=1 TO 1658880
@22,20 SAY j
SELECT 1
GO j
sss=素数式
bpz=sss+(i-1)*bcz               &&计算被判断值
Kf=INT(SQRT(bpz))                   &&求出被判断值的开方根
SELECT 2
GO 1
COUNT ALL FOR 素数<=kf TO jlh  &&借用原来的记录号，实际上统计kf以前的素数个数
  && jlh=RECNO()
SELECT 2   
GO 9                                &&从第二条记录开始读取素数(3)
FOR k=1 TO jlh-8                     &&内循环开始。这个循环实质上是从小到大顺序,依次读取素数。循环值是记录序号
qmz=MOD(bpz,素数)                   &&以读取的素数为条件,对被判断值求模
IF qmz=0 && OR qmz=2 OR qmz=6 OR qmz=8  如果符合这四个约定条件之一,就进行相应工作.如果一个也没有符合条件的,直接使记录指针向下移动一个(SKIP)
EXIT                                &&因为符合条件,则做完相应工作后跳出内循环
ENDIF
SKIP                                &&素数表指针向下移动一个
ENDFOR
IF k>jlh-8
SELECT 3               &&打开保存求解结果的信息表
APPEND BLANK                        &&增加一条空记录
REPLACE 素数 WITH bpz && 把bpz赋给素数        
ENDIF
ENDFOR
ENDFOR
=MESSAGEBOX("运行时间："+LTRIM(STR(INT((SECONDS()-kssj)/60)))+"分"+LTRIM(STR(MOD(SECONDS()-kssj,60),5,2))+"秒",64,"运行时间提示")
一个一个的处理方法用时：65分41.26秒，明显比一个批次一个批次处理要慢的多。

可否分享成品DBF文件

程序需要用到的五个表上传在这里（它们是自由表，已从数据库中导出，只是表明加了后缀---副表2字，其他未变动），程序在31楼，对应着稍微修改就可以用了。（路径及表名等信息）

在31楼已经有了程序。另外在37楼所用表已经全部上传。静候您的佳音。

40000000以内耗时173s，破电脑就这速度。
用数组应该可以算到超过1亿内，每个数组中元素的最大数目 一般: 2G 字节、成员数组: 2G 字节

输出文件可以设置默认路径或指定路径

* 改造了31楼的程序，结果表记录1234399，用时350秒
CLEAR
CLOSE DATABASES

LOCAL kkk

SELECT 1
USE 数据源.DBF ALIAS 数据源
SELECT 2
USE 素数表.DBF ALIAS 素数表参

SELECT 5
USE 素数结果.DBF ALIAS 素数表果
DELETE ALL
PACK

SELECT 素数 数据1 FROM 素数表果 WHERE 1=2 INTO CURSOR 数据a READWRITE

kssj = DATETIME()
FOR i=1 TO 2
    SELECT 素数式+(i-1)*9699690 数据1,CAST(1 as INT) 数据mod FROM 数据源 INTO CURSOR 数据a READWRITE

    SELECT 数据a
    GO BOTTOM     &&1658880
    Kf=INT(SQRT(数据1))

    SELECT 2
    kkk = 0
    SCAN FOR RECNO()>8 AND 素数<=kf
        IF RECNO()>kkk
            WAIT TRANSFORM(RECNO()) WINDOW NOWAIT NOCLEAR
            kkk = kkk + 10
        ENDIF
        
        UPDATE 数据a SET 数据mod=MOD(数据1,素数表参.素数) WHERE 数据mod>0

        SELECT 2
    ENDSCAN
   
    INSERT INTO 素数表果 (素数) SELECT 数据1 FROM 数据a WHERE 数据mod>0
   
 ENDFOR
 USE IN 数据a
 
 MESSAGEBOX( DATETIME()-kssj)
 SELECT 素数表果
 MESSAGEBOX( RECCOUNT())
 BROWSE
 

首先多谢先生的回答。我还没有运行。那也比我原来的提速不少。

我的48楼答非所问。是我没有看懂各位的提问。多言了。吹水佬没有用到数据源（用不用素数表不重要，因为此主题的目的是要用到数据源，形成分段运算，更深层目的没有明说（计划改造后用到其他程序中去））。