如何让程序预定执行一段代码（定时或闲时）

以下是引用大树临风在2021-3-11 11:40:02的发言：

感谢版主，单线程意味着timer触发后，会造成主程序的“卡顿”是吧，那有没有什么更好的办法？
我的目的就是定时从腾讯云COS上读取一段文本信息，然后显示出来

以下是引用吹水佬在2021-3-11 10:56:28的发言：

timer是定时器，也是工作在单线程，要注意的是timer有可能“不定时”或“不准时”，甚至是“没有时”。

以下是引用吹水佬在2021-3-11 12:52:43的发言：

定时器的级别很低，其他任务太忙时有可能会被放弃

以下是引用大树临风在2021-3-11 11:40:02的发言：


提到单线程，想起来每次编译EXE时VFP弹出的对话框，其中的单线程dll和多线程dll又是什么意思呢，是不是也可以做多线程的开发

以下是引用radiofan在2021-3-11 16:21:56的发言：



没有明白？

以下是引用吹水佬在2021-3-12 12:12:12的发言：

最简单的示例（消息）

** 主进程
** test1.exe
**
cDefPath = ADDBS(JUSTPATH(SYS(16)))
_screen.Visible = .F.
DECLARE LONG SendMessage IN User32 LONG, LONG, LONG, LONG
of = CREATEOBJECT("Form1")
of.show
READ EVENTS
RETURN

DEFINE CLASS Form1 as Form
    ShowWindow = 2
    hSubpro = 0
    ADD OBJECT cmd as CommandButton WITH top=10,left=10,height=22,caption="启动子进程"
    ADD OBJECT edt as EditBox WITH top=40,left=10,width=300,height=200
   
    PROCEDURE Init
        BINDEVENT(this.hWnd, 0x401, this, "_Message")
    ENDPROC
   
    PROCEDURE Destroy
        IF this.hSubpro > 0
            SendMessage(this.hSubpro, 0x401, 0, 0)
        ENDIF
        CLEAR EVENTS
    ENDPROC
   
    PROCEDURE cmd.Click
        oApp = CREATEOBJECT("Shell.Application")
        oApp.ShellExecute(cDefPath+"test2.exe", TRANSFORM(thisform.hWnd), "", "", 1)
    ENDPROC

    PROCEDURE _Message(hWnd, nMsg, wParam, lParam)
        DO CASE
            CASE wParam == 1
                this.edt.SelText = "子进程启动" + 0h0D0A
                this.hSubpro = lParam
            CASE wParam == 2
                this.edt.SelText = "子进程关闭" + 0h0D0A
        ENDCASE
    ENDPROC
ENDDEFINE


** 子进程
** test2.exe
**
PARAMETERS cParam
_screen.Visible = .F.
DECLARE LONG SendMessage IN User32 LONG, LONG, LONG, LONG
of = CREATEOBJECT("Form1", cParam)
of.show
READ EVENTS
RETURN

DEFINE CLASS Form1 as Form
    ShowWindow = 2
    AutoCenter = 1
    hMain = 0
   
    PROCEDURE Init(cParam)
        this.hMain = INT(VAL(cParam))
        SendMessage(this.hMain, 0x401, 1, this.hWnd)
        BINDEVENT(this.hWnd, 0x401, this, "_Message")
    ENDPROC
   
    PROCEDURE Destroy
        IF this.hMain> 0
            SendMessage(this.hMain, 0x401, 2, 0)
        ENDIF
        CLEAR EVENTS
    ENDPROC
   
    PROCEDURE _Message(hWnd, nMsg, wParam, lParam)
        DO CASE
            CASE wParam == 0
                MESSAGEBOX("主程序关闭")
                this.Release
            CASE wParam == 1
            CASE wParam == 2
        ENDCASE
    ENDPROC
ENDDEFINE

以下是引用吹水佬在2021-3-12 18:47:39的发言：


每分钟启动子进程一次就没必要。
启动子进程后就可以一直工作，直到完成整个任务，什么时候需要子进程做什么是可以控制。

以下是引用xuminxz在2021-9-24 10:52:42的发言：

似乎可以用windows的计划任务程序，来调用你的程序。