VB怎么把一个文件复制到内存,是复制到内存里!!

#2

cwa99582020-08-28 08:22

用来复制用？那可以放到粘贴板上嘛。
粘贴板对象是Clipboard
对于文本，用settext方法。图形，用setdata方法。

SetText 方法示例
本示例使用 SetText 方法从一个文本框中复制文本到剪贴板。要检验此示例，可将本例代码粘贴到一个带有名为 Text1 的窗体的声明部分，然后按 F5 键并单击该窗体。

Private Sub Form_Click ()
   Const CF_TEXT = 1   ' 定义位图各种格式。
   Dim I, Msg, Temp   ' 声明变量。
   On Error Resume Next   ' 设置错误处理。
   Msg = "Type anything you like into the text box below."
   Text1.Text = InputBox(Msg)   ' 取得用户正文。
   Msg = "Choose OK to copy the contents of the text box "
   Msg = Msg & "to the Clipboard."
   MsgBox Msg   ' 显示信息。
   ClipBoard.Clear   ' 清除剪贴板。
   Clipboard.SetText Text1.Text   ' 将正文放置在剪贴板上。
   If Clipboard.GetFormat(CF_TEXT) Then
      Text1.Text = ""   ' 清除该正文框。
      Msg = "The text is now on the Clipboard. Choose OK "
      Msg = Msg & "to copy the text from the Clipboard back "
      Msg = Msg & "to the text box."
      MsgBox Msg   ' 显示信息。
      Temp = Clipboard.GetText(CF_TEXT)   ' 取得剪贴板正文。
      For I = Len(Temp) To 1 Step -1   ' 使该正文反向。
         Text1.Text = Text1.Text & Mid(Temp, I, 1)
      Next I
   Else
      Msg = "There is no text on the Clipboard."
      MsgBox Msg   ' 显示错误信息。
   End If
End Sub

#3

风吹过b2020-08-28 11:24

他是要把文件的复制信息保存到剪贴板上。需要构建二进制数据保存到剪贴板上去。这个数据格式目前我不知道。

其实一些多重剪贴板软件应该可以达到你的目的。

#4

elik7202020-08-29 21:51

以下是引用风吹过b在2020-8-28 11:24:19的发言：

他是要把文件的复制信息保存到剪贴板上。需要构建二进制数据保存到剪贴板上去。这个数据格式目前我不知道。

其实一些多重剪贴板软件应该可以达到你的目的。

大佬你去研究下贝你们毕竟经验丰富稍微研究一下然后就可以把源代码写出来了

我问的问题看上去还是很直白的要求或许实现起来麻烦一点我想你们只要去研究肯定可以把文件复制进内存楼上的那个是把文本内容复制进内存和我需要的完全是2码事了

#5

风吹过b2020-08-30 11:52

昨天晚上百度了一圈，然后，只看到一个使用C++的代码，并且有一个结构到处没找到定义，然后对后面的数据是怎么样的格式也不太清楚。
里面有一个标记，复制还是剪切，然后这个代码里注释说自定义标志

。
算了，不折腾了。本来就英文不行，然后这里全是API操作，VB自带的可能不支持这里的操作。

#6

elik7202020-08-31 23:27

回复 2楼 cwa9958

你这回复的不对啊  明人不说暗话

我要的是  复制文件到剪贴版   txt文件  不是 txt文本里面的内容    复制进内存后  无论任何的电脑目录下      右键黏贴是亮的   按CTRL+V 可以黏贴出文本文件的

你发的这个代码网上很容易找到的  没什么用

我网上找了半天   的确实现起来或许会很麻烦   如果没有先人写过类似的功能,要自己研究寻找函数肯定要花时间     看上去简单的功能,可不要难倒一大片啊

[此贴子已经被作者于2020-8-31 23:31编辑过]

#7

cwa99582020-09-03 13:01

要复制文件，粘贴用Ctrl+V，还不是用了系统的粘贴板吗？
粘贴板是系统共用的，在别的地方更新了粘贴板怎么办？
还真不知道你要怎么用，系统的粘贴板应该是在内存里的吧

#8

William19492020-09-03 14:25

楼主是不是想要这种效果：

程序代码：

Option Explicit
Private Declare Function OpenClipboard Lib "user32" (ByVal hWnd As Long) As Long
Private Declare Function EmptyClipboard Lib "user32" () As Long
Private Declare Function CloseClipboard Lib "user32" () As Long
Private Declare Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
Private Const GMEM_MOVEABLE = &H2
Private Const GMEM_ZEROINIT = &H40
Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long

Private Declare Function SetClipboardData Lib "user32" (ByVal wFormat As Long, ByVal hMem As Long) As Long
Private Const CF_HDROP = &HF

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Private Type POINTAPI
    X       As Long
    Y       As Long
End Type
Private Type DROPFILES
    pFiles  As Long
    pT      As POINTAPI
    fNC     As Long
    fWide   As Long
End Type

Private Sub Command1_Click()
    Dim FileName  As String

    FileName = "C:\a.txt"
    If Dir(FileName) = "" Then Exit Sub
    FileName = FileName & vbNullChar & vbNullChar
    Call FileToClipboard(FileName)
End Sub

Private Sub FileToClipboard(ByVal FileName As String)
    Dim dFiles  As DROPFILES
    Dim hMem    As Long, MemPtr   As Long, Len1 As Long, Len2 As Long

    If OpenClipboard(Me.hWnd) = 0 Then Exit Sub
    Call EmptyClipboard
    Len1 = Len(dFiles)
    Len2 = LenB(StrConv(FileName, vbFromUnicode))
    hMem = GlobalAlloc(GMEM_MOVEABLE Or GMEM_ZEROINIT, Len1 + Len2)
    MemPtr = GlobalLock(hMem)
    dFiles.pFiles = Len1
    Call CopyMemory(ByVal MemPtr, dFiles, Len1)
    Call CopyMemory(ByVal (MemPtr + Len1), ByVal FileName, Len2)
    Call GlobalUnlock(hMem)
    Call SetClipboardData(CF_HDROP, hMem)
    Call CloseClipboard
End Sub

#9

风吹过b2020-09-03 16:06

应该是这种的。我前就是没找到那个结构的定义。
    Call EmptyClipboard            打开剪切板
    Len1 = Len(dFiles)             结构长度
    Len2 = LenB(StrConv(FileName, vbFromUnicode))   文件名长度
    hMem = GlobalAlloc(GMEM_MOVEABLE Or GMEM_ZEROINIT, Len1 + Len2)   申请剪切板内存
    MemPtr = GlobalLock(hMem)      锁定剪切板内存
    dFiles.pFiles = Len1
    Call CopyMemory(ByVal MemPtr, dFiles, Len1)       结构体写入剪切板内存
    Call CopyMemory(ByVal (MemPtr + Len1), ByVal FileName, Len2)   结构体后写入文件名
    Call GlobalUnlock(hMem)        开锁剪切板内存
    Call SetClipboardData(CF_HDROP, hMem)    设置剪切板内容
    Call CloseClipboard            关闭剪切板

#10

elik7202020-09-05 12:11

回复 8楼 William1949

对对对你这个和我花了150大洋别人写给我的一样要是早点给我就不用花钱了

#11

elik7202020-09-05 12:11

以下是引用风吹过b在2020-9-3 16:06:17的发言：

应该是这种的。我前就是没找到那个结构的定义。
    Call EmptyClipboard            打开剪切板
    Len1 = Len(dFiles)             结构长度
    Len2 = LenB(StrConv(FileName, vbFromUnicode))   文件名长度
    hMem = GlobalAlloc(GMEM_MOVEABLE Or GMEM_ZEROINIT, Len1 + Len2)   申请剪切板内存
    MemPtr = GlobalLock(hMem)      锁定剪切板内存
    dFiles.pFiles = Len1
    Call CopyMemory(ByVal MemPtr, dFiles, Len1)       结构体写入剪切板内存
    Call CopyMemory(ByVal (MemPtr + Len1), ByVal FileName, Len2)   结构体后写入文件名
    Call GlobalUnlock(hMem)        开锁剪切板内存
    Call SetClipboardData(CF_HDROP, hMem)    设置剪切板内容
    Call CloseClipboard            关闭剪切板

老铁牛B 解释的到位虽然还是不懂吼吼看不懂你的注释是因为不了解内存结构为什么要这样写所以不太懂

#12

风吹过b2020-09-05 14:07

我前面查的资料，
复制文件，在剪切板中数据格式为：结构+文件名
所以要先创建一个结构，然后在结构填充必要的数据，
再申请剪切板专用内存，然后把结构和文件名依次放到这个指定内存中去。
因Windows是多任务操作系统，所以操作剪切板内存时，需要锁定这个内存，锁定后，其他应用在锁定期间，就无法再操作这块内存，防止冲突。详情请去了解多进程（线程）间通讯或共享内存操作。

VB怎么把一个文件 复制到内存,是复制到内存里!!