求助，关于删除电脑所有盘同名应用程序代码！

Option Explicit

Private Declare Function GetLogicalDriveStrings Lib "kernel32" Alias "GetLogicalDriveStringsA" (ByVal nBufferLength As Long, ByVal lpBuffer As String) As Long
Private i As Integer
Private MyFile As String

Private Sub Command1_Click()
Dim m&, d$, s$()

    On Error Resume Next
    d = String(256, Chr(0))                 '盘符缓冲区
    GetLogicalDriveStrings Len(d), d        '取盘符列表
    m = InStrRev(d, "\")                    '最后一个 \ 的位置
    d = Left(d, m)                          '保留有的字符
    s = Split(d, Chr(0))                    '分解成数组
   
    i = 0                                   '计数变量
    For m = 0 To UBound(s)                  '遍类数组
        If Len(s(m)) > 0 Then               '数据有效
            Call OutFile2(s(m), "b.exe")    '调用子程序进行检索是否存在
        End If
    Next m
   
    Text1.Text = "搜索结果:" & vbCrLf & MyFile '文本框设为多行显示被找到的文件清单
   MsgBox "一共找到并删除：" & i & " 个文件"
End Sub

Private Sub OutFile2(ByVal MyFolder As String, ByVal MyFileName As String)
'    On Error Resume Next
Dim fs As Object, f As Object
Dim sf As Object
    Set fs = CreateObject("Scripting.FileSystemObject")     '创建FSO
If Right(MyFolder, 1) <> "\" Then                           '路径最后添加 \
    MyFolder = MyFolder & "\"
End If

Set f = fs.GetFolder(MyFolder)
For Each sf In f.Files                      '所有的文件
    If sf.Name = MyFileName Then            '不支持通配符的比较，如果需的，那么就要写正则表达式
        'Kill MyFolder & MyFileName '删除文件
        i = i + 1
        MyFile = MyFile & MyFolder & MyFileName & vbCrLf
    End If
Next

For Each sf In f.SubFolders                 '所有的目录
    Call OutFile2(sf.Path, MyFileName)      '递归调用自己
Next

End Sub