类模块的问题 - 编程论坛

#2

wube2014-12-08 12:50

例如:
Form1(Main Form) :
---------------------------------------------------------------------------
Private WithEvents AAA As ClsABCD
...
...
Private Sub AAA_BackStruct(ByVal PNum As Integer, ByVal FNum As Integer)
MsgBox "No !"
End Sub
---------------------------------------------------------------------------
Form2 :
---------------------------------------------------------------------------
Private WithEvents BBB As ClsABCD
...
...
Private Sub BBB_BackStruct(ByVal PNum As Integer, ByVal FNum As Integer)
MsgBox "OK !"
End Sub
---------------------------------------------------------------------------
Class ClsABCD :
---------------------------------------------------------------------------
Public Event BackStruct(ByVal iPNum As Integer, ByVal iFNum As Integer)
...
...
...
...
RaiseEvent BackStruct(1, FlowNum)'但是每到这行就会跳到Main Form里的SUB中
...
...
---------------------------------------------------------------------------
不知道我是漏了什么?我两边都有类事件返回的需求.

#3

风吹过b2014-12-08 17:06

我测试的结果是，
如果是不同的类，那么是分别返回的。
如果是同一个类，就同时在这个二个窗体上返回。

#4

wube2014-12-09 00:16

如果是同一个类，就同时在这个二个窗体上返回。

你能用同个类对分别对两个不同表单上对指定的控件透过类事件返回去做动作吗？
要怎做？

#5

wube2014-12-09 00:43

Public Event BackStruct(ByVal iPNum As Integer, ByVal iFNum As Integer)
...
RaiseEvent BackStruct(1, FlowNum)'但是每到这行就会跳到Main Form里的SUB中
...

越想也越怪，单凭关键这两行，ＶＢ怎去判断事件应该要回应到哪个表单裡．
是哪边可以设定吗？不然就是预设都只回应主表单。
但是奇怪的是，在不同表单用不同对象去new一个类后，两个表单都自动会有相应的事件函式可供人使用。
或是关键在于起始表单先new一个类后，自然决定要返回的目标，所以难道你是在某一表单内定义：
Public WithEvents AAA As ClsABCD
但我印象中，类事件好像不能宣告成Public，而且还一定得写在表单裡。
好乱，用两个不同对象去对相同一个类，期望能在触发类事件时，让代码的执行权自动切换到不同表单运行，应该是不行。

#6

风吹过b2014-12-09 10:37

第一个窗体，是按你这个猜想去的。
Public WithEvents AAA As ClsABCD
然后
set AAA = new ClsABCD
第二个窗体，
set BBB = ClsABCE
这样二个窗体引用同一个类。类里的事件，两个窗体同时显示，我测试时，是开了二个窗体，关掉一个窗体我没去测试。

-----------------------
如果
第二个窗体
set BBB = new ClsABCD
那么事件响应就是各自的窗体响应对应的类。

---------------------
----Form1------
Public WithEvents AAA As ClsABCD
Private Sub AAA_BackStruct(ByVal PNum As Integer, ByVal FNum As Integer)
    MsgBox "No 1"
End Sub
Private Sub Command1_Click()
    Call AAA.ev
End Sub
Private Sub Form_Load()
Set AAA = New ClsABCD
Form2.Show
End Sub

----Form2------
Private WithEvents BBB As ClsABCD
Private Sub BBB_BackStruct(ByVal PNum As Integer, ByVal FNum As Integer)
    MsgBox "No 2"
End Sub
Private Sub Command1_Click()
    Call BBB.ev                 '手动触发事件
End Sub

Private Sub Form_Load()
Set BBB = Form1.AAA
'Set BBB = New ClsABCD
End Sub

----ClsABCD--------
Public Event BackStruct(ByVal iPNum As Integer, ByVal iFNum As Integer)
Const Flownum = 2
Public Sub ev()
    RaiseEvent BackStruct(1, Flownum)
End Sub

#7

wube2014-12-09 14:32

在Form2 :
1. 写成 set BBB = ClsABCE 光源码编译就过不了.
2. 写成 Set BBB = Form1.AAA 源码编译就过了.
--------------------------------------------------------------------
直接试了你的源码发现你设计的功能好像跟我要的刚好相反.
不过也差不多,也因此找到解决方向了.
--------------------------------------------------------------------

Form1:--------------------------------------------------------------
Public WithEvents AAA As ClsABCD
Private Sub AAA_Back()
    Form1.Hide
    Form2.Show
End Sub
Private Sub AAA_BackStruct(ByVal iCount As Integer)
    ProgressBar1.Value = iCount
End Sub
Private Sub Command1_Click()
    With AAA
        .nCount = 100
        .Run
    End With
End Sub
Private Sub Form_Load()
    Set AAA = New ClsABCD
    ProgressBar1.Value = 0
    Form2.Show
    Form2.Hide
End Sub
Form2:--------------------------------------------------------------
Private WithEvents BBB As ClsABCD
Private Sub BBB_BackStruct(ByVal iCount As Integer)
    ProgressBar1.Value = iCount
End Sub
Private Sub Form_Load()
    Set BBB = Form1.AAA
    ProgressBar1.Value = 0
End Sub
ClsABCD:--------------------------------------------------------------
Private mvarnCount As Integer
Public Event BackStruct(ByVal iCount As Integer)
Public Event Back()
Public Property Let nCount(ByVal vData As Integer)
    mvarnCount = vData
End Property
Public Sub Run()
Dim i As Integer, j As Integer
    For i = 0 To mvarnCount
        RaiseEvent BackStruct(i)
    Next i
    RaiseEvent Back
    For j = 0 To mvarnCount
        RaiseEvent BackStruct(j)
    Next j
End Sub