编程论坛 → VB6论坛

关于VB6处理xml的问题~各位爷来看下吧~

qq190169573 发布于 2013-11-17 17:07， 546 次点击

我想对xml进行处理
对xml中rec节点下
所有节点的x值乘以2
现在我遇到的问题是
同一层级的我可以理解
但是多层的我就不会了
求大家指点下~

程序代码：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <element folder="activity">
        <rec x="0" y="0">
            <sprite x="1,2"/>
            <sprite x="20"/>
            <sprite key="allActivity" t="rec" x="30">
                <sprite key="ever1" n="everyActivity" t="rec" x="2,4,6,8">
                    <sprite key="boxty" n="boxty" x="3"/>
                    <sprite key="iconActivity" n="iconActivity" statelist="0,1,2,3" t="si" x="3"/>
                    <sprite key="culeMC" n="cube64" t="cmc" fps="24" x="3"/>
                    <sprite key="shbei" n="shbei" x="3"/>
                </sprite>
                <sprite key="ever2" n="boxvity" x="2"/>
            </sprite>
            <sprite key="hehe" n="hehe" statelist="0,1,2,3" x="15" />
        </rec>
    </element>
</root>

这是需要处理的xml
我希望涉及到x的地方，无论层级有多深~ 都将x的值乘以2.
如果x有多个值以“，”隔开的话，也要乘以2~~~~~

下面是我的一些代码，
太不完善了
无法达到我的效果
求大神拯救阿...
程序代码：
[color=#0000FF]Private Sub Command1_Click()
Dim Dom As New DOMDocument
Dom.async = False
Dim x As IXMLDOMNode
Dim node As IXMLDOMNode
Dim arr
Dim brr

'加载xml
Add = "E:\ts.xml"
Dom.Load Add
Set node = Dom.selectSingleNode("root").selectSingleNode("element").selectSingleNode("rec")
For Each x In node.childNodes
     '获取限定值
     xvalue = x.Attributes.getNamedItem("x").Text

     '判断如果x存在多个值，将值x2
     If InStr(xvalue, ",") Then
        arr = Split(xvlaue, ",")
        For i = LBound(arr) To UBound(arr)
            brr = arr(i) * 2
            x.Attributes.getNamedItem("x").Text = brr(i)
        Next
     Else
        '输出双倍的x
        '并保存
        x.Attributes.getNamedItem("x").Text = xvalue * 2
        Dom.save (Add)
     End If
Next
Set Dom = Nothing
MsgBox "双倍执行完毕"
End Sub
.

[/color]

6 回复

#2

qq1901695732013-11-17 17:08

..搞了一天了
没想明白

#3

bczgvip2013-11-17 20:28

程序代码：

Option Explicit

Private Sub Command1_Click()
    Dim xmlDoc As New DOMDocument
    xmlDoc.async = False
    Dim tNode As IXMLDOMNode
    Dim xmlFN As String

    '加载xml
    xmlFN = "E:\ts.xml"
    xmlDoc.Load xmlFN
    Set tNode = xmlDoc.selectSingleNode("root").selectSingleNode("element").selectSingleNode("rec")
    TraversalNode tNode
    xmlDoc.save (xmlFN)
    Set xmlDoc = Nothing
End Sub

Private Sub TraversalNode(tNode As Object)
    Dim tmpNode As IXMLDOMNode 'IXMLDOMNode Object
    For Each tmpNode In tNode.childNodes
        If Not tmpNode.firstChild Is Nothing Then TraversalNode tmpNode
        MyReplace tmpNode
    Next
End Sub

Private Sub MyReplace(tNode As Object)
    Dim sValue As String
    Dim sArr() As String
    Dim tmpObj As Object
    Dim i As Long
    Set tmpObj = tNode.Attributes.getNamedItem("x")
    If tmpObj Is Nothing Then Exit Sub
    sValue = tmpObj.Text
    If InStr(sValue, ",") Then
        sArr = Split(sValue, ",")
        For i = LBound(sArr) To UBound(sArr)
            sArr(i) = CLng(sArr(i)) * 2
        Next
        tmpObj.Text = Join(sArr, ",")
    Else
        tmpObj.Text = sValue * 2
    End If
End Sub

' 新人都不喜欢自定义函数么？哪怕功能函数也行呐？
' 函数调用自身那叫啥？呃，一时间忘了。

#4

lowxiong2013-11-17 20:58

Private Sub Command1_Click()
  Dim Dom As New DOMDocument
  Dom.async = False
  Dim x As IXMLDOMNode
  Dim node As IXMLDOMNode
  Dim arr() As String
  Dim brr As String
  Dim xvalue As String
  '加载xml
  Dom.Load "E:\ts.xml"
  Set node = Dom.selectSingleNode("root").selectSingleNode("element").selectSingleNode("rec")
  For Each x In node.childNodes
       '获取限定值
       xvalue = x.Attributes.getNamedItem("x").Text

       '判断如果x存在多个值，将值x2
       If InStr(xvalue, ",") Then
          arr = Split(xvalue, ",")
          brr = ""
          For i = LBound(arr) To UBound(arr)
              arr(i) = Val(arr(i)) * 2
              brr = brr & arr(i) & ","
          Next
          x.Attributes.getNamedItem("x").Text = Left(brr, Len(brr) - 1)
       Else
          '输出双倍的x
          '并保存
          x.Attributes.getNamedItem("x").Text = xvalue * 2

       End If
  Next
  Dom.save ("e:\ts1.xml")
  Set Dom = Nothing
  MsgBox "双倍执行完毕"
End Sub
'1，要正确定义类型  2，未正确进行字符串运算  3，Dom.save 语句位置错
'为方便调试，修改后的文件为ts1.xml，本代码只能地rec节点内的x值修改，rec节点内子节点的x值不能修改

#5

lowxiong2013-11-18 01:09

回复 3楼 bczgvip

顶一下。那叫递归。

#6

风吹过b2013-11-18 18:02

递归，

递归有次数限制的，具体看内存的大小。一般用不完就是的。

一般循环都可以写成递归，递归很难写成循环，听说有牛人把汉诺塔写成的循环。

#7

qq1901695732013-11-18 22:57

谢谢两委版主大大，我会认真学习de

1