ASP如何在网页中输出ACCESS某表中某条记录的非空字段名及其值？ - 编程论坛

#2

ysf01812013-01-24 15:23

Function IsBlank_config1(ByRef TempVar)
'by default, assume it's not blank
IsBlank_config1 = False
'now check by variable type
Select Case VarType(TempVar)
'Empty & Null
Case 0, 1
IsBlank_config1 = True
'String
Case 8
If Len(TempVar) = 0 Then
IsBlank_config1 = True
End If
'Object
Case 9
tmpType = TypeName(TempVar)
If (tmpType = "Nothing") Or (tmpType = "Empty") Then
IsBlank_config1 = True
End If
'Array
Case 8192, 8204, 8209
'does it have at least one element?
If UBound(TempVar) = -1 Then
IsBlank_config1 = True
End If
End Select
End Function
'应用实例：
'If IsBlank_config1(rs("upic")) Then
' upicurl="/images/nonepic.jpg"
' Else
' upicurl=rs("upic")
' End If

#3

ASP入门者2013-01-25 01:27

回复 2楼 ysf0181

上面的有些看不懂，下面是显示全部字段名和值的代码，请高手帮改下看能达到目的否，十分感谢！

<%@ language=VBScript %>
<%
dim connstr
connstr="provider=Microsoft.jet.oledb.4.0;data source=" &server.mappath("mydata.mdb")
set conn=server.createobject("adodb.connection")
conn.open connstr
%>

<%
dim TabelName,i,rs
TableName="type"  '这里设置数据库中的特定表名
set rs=server.CreateObject("adodb.recordset")
rs.open "select * from "&TableName&" where 类型='简略型'",conn,1,1   '对指定数据库表进行查询
response.write "<table border=""1"">"
response.write "<tr bgcolor=""#cccccc"">"
for i=0 to rs.fields.count-1
response.write "<th>"&rs.fields(i).name & "</th>"  '输出表中所有字段名
next
response.write "</tr>"

'开始输出所有记录值
do while not rs.eof
    response.write "<tr bgcolor=""#ffffff"">"
    for i=0 to rs.fields.count-1
        response.write "<td>"
        if isnull(rs.fields(i).value) then
            response.write ""
        elseif rs.fields(i).value="" then
            response.write "空"
        else
            response.write server.HTMLEncode(rs.fields(i).value)
        end if
        response.write "</td>"
    next
    rs.movenext
    response.write "</tr>"
loop

response.write "</table>"

%>

[ 本帖最后由 ASP入门者于 2013-1-25 01:31 编辑 ]

#4

ASP入门者2013-01-26 13:12

回复楼主 ASP入门者

呵呵，自己已经解决。。。。这个论坛好象有点冷，是不是自己的态度不好？

[ 本帖最后由 ASP入门者于 2013-1-26 13:13 编辑 ]

#5

hu9jj2013-01-26 16:20

以下是引用ASP入门者在2013-1-26 13:12:07的发言：

呵呵，自己已经解决。。。。这个论坛好象有点冷，是不是自己的态度不好？

数九寒冬，当然有点冷。不过春天不远了，论坛很快就会热起来的。