（关于文本控件属性值保存的问题）我需要自动保存一些设置好的信息该怎么写呢！

Option Explicit

Private Sub Command1_Click()
    SaveSettingEx Text1, Text2, Text3, Text4, Text5, Text6
End Sub

Private Sub Command2_Click()
    DeleteSettingEx Text1, Text2, Text3, Text4, Text5, Text6
End Sub

Private Sub Form_Load()
    Me.Width = GetSetting(App.Title, Me.Name, "Width", 7200)
    Me.Height = GetSetting(App.Title, Me.Name, "Height", 6300)
    Me.Top = GetSetting(App.Title, Me.Name, "Top", 100)
    Me.Left = GetSetting(App.Title, Me.Name, "Left", 100)
    GetSettingEx Text1, Text2, Text3, Text4, Text5, Text6
End Sub

Private Sub Form_Unload(Cancel As Integer)
    If Me.WindowState <> vbMinimized Then '最小化退出有点问题。负值
        Call SaveSetting(App.Title, Me.Name, "Width", Me.Width)
        Call SaveSetting(App.Title, Me.Name, "Height", Me.Height)
        Call SaveSetting(App.Title, Me.Name, "Top", Me.Top)
        Call SaveSetting(App.Title, Me.Name, "Left", Me.Left)
    End If
End Sub

Public Sub DeleteSettingEx(ParamArray vControls() As Variant)
    Dim v As Variant
    For Each v In vControls
        If TypeOf v Is TextBox Then ' 可以自行添加别的控件设置 CommandButton TextBox 等
            Call DeleteSetting(App.Title, Me.Name, v.Name)
        End If
    Next
End Sub

Public Sub GetSettingEx(ParamArray vControls() As Variant)
    Dim v As Variant
    For Each v In vControls
        If TypeOf v Is TextBox Then ' 可以自行添加别的控件设置 CommandButton TextBox 等
            v.Text = GetSetting(App.Title, Me.Name, v.Name, "默认值") '默认值自己设置
        End If
    Next
End Sub

Public Sub SaveSettingEx(ParamArray vControls() As Variant)
    Dim v As Variant
    For Each v In vControls
        If TypeOf v Is TextBox Then
            Debug.Print Me.Name, v.Name, v.Text
            Call SaveSetting(App.Title, Me.Name, v.Name, v.Text)
        End If
    Next
End Sub