请问怎么移动无标题的窗体，因控件多以至用不了Form的有关事件 - 编程论坛

#2

seafish0112013-01-16 10:56

有大手能给出思路怎么弄么？

#3

lowxiong2013-01-16 11:01

你就让其中的一个控件（如某个标签，因为标签多作为显示用，没有响应鼠标键盘的功能）的MouseMove事件作为移动整个窗体的事件不就可以了。

#4

bczgvip2013-01-16 15:32

有多少个控件?

#5

seafish0112013-01-16 23:30

回复 3楼 lowxiong

嗯，这个我也有想过，不过我是动态添加控件的，所以那些控件我也没法用得上MouseMove事件。
对于这个情况我想到另一种思路：可不可以监视鼠标坐标，如果鼠标mousedown 则记录窗体以及鼠标的坐标，鼠标mousemove时鼠标得到新坐标，窗体坐标也相应移动（不知道这样行得通不）。但是感觉有点复杂了！！所以想问问大手们有没有什么好方法。

#6

seafish0112013-01-16 23:34

回复 4楼 bczgvip

这个真没数过，有些动态添加进去的，有些控件随鼠标的移动或者点击又有不同的事件。

#7

bczgvip2013-01-17 01:10

程序代码：

Option Explicit

Private Declare Function ReleaseCapture Lib "user32" () As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Const WM_NCLBUTTONDOWN As Long = &HA1
Private Const HTCAPTION As Long = 2

Private Sub Command1_Click(Index As Integer)
    Debug.Print "Command1_Click", Index
End Sub

Private Sub Form_Load()
    Dim w&, h&, i&, j&, n&
    w = Me.ScaleWidth \ Command1(0).Width
    h = Me.ScaleHeight \ Command1(0).Height
    n = w * h
    Command1(0).Caption = "0"
    For i = 1 To n - 1
        Load Command1(Command1.UBound + 1)
        Command1(Command1.UBound).Left = Command1(Command1.UBound - 1).Left + Command1(Command1.UBound - 1).Width
        Command1(Command1.UBound).Top = Command1(Command1.UBound - 1).Top
        If i Mod w = 0 Then
            Command1(Command1.UBound).Left = Command1(Command1.UBound - w).Left
            Command1(Command1.UBound).Top = Command1(Command1.UBound - 1).Top + Command1(Command1.UBound - 1).Height
        End If
        Command1(Command1.UBound).Caption = i
        Command1(Command1.UBound).Visible = True
    Next
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Button = 1 Then
        Call ReleaseCapture
        Call SendMessage(hWnd, WM_NCLBUTTONDOWN, HTCAPTION, ByVal 0&)
    End If
End Sub

Private Sub Command1_MouseMove(Index As Integer, Button As Integer, Shift As Integer, X As Single, Y As Single)
    Form_MouseMove Button, Shift, X, Y
End Sub

自己测试吧，添加一个按钮数组。话说，你是用别的移动窗口的方法吧？

#8

wube2013-01-17 15:31

简单点的方法～若是我我应该会找个背景透明的控件～
整个贴到窗体上变成一个虚拟的窗体～然后再用去MouseMove做移动～
因为透明使用者也不会知道～