100分求批量删除指定子文件夹的DOS命令 - 编程论坛

#2

静夜思2009-10-24 16:30

动用一下私权全局置顶，请大家见谅，问题解决后即取消置顶。

#3

aspic2009-10-24 16:59

程序代码：

@echo off
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了临时VBS代码进行日期计算
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstDate%" (
    if exist "%%a" (
      echo del /f /q "%%a"
    )
  )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
【方案二】删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件：BAT + REG + Ritchie Lawrence 日期函数
复制内容到剪贴板代码:
@echo off
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了 Ritchie Lawrence 的日期函数进行日期计算
::日期转换的核心算法请参考http://bbs.
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstDate%" (
    if exist "%%a" (
      echo del /f /q "%%a"
    )
  )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
【方案三】删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件：BAT + VBS
复制内容到剪贴板代码:
@echo off
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了临时VBS代码进行日期计算，并统一设置系统日期格式，处理完毕
::之后再把日期格式恢复成原来的状态。摆脱了对reg命令（XP系统自带）的依赖。

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
>"%temp%\BackupDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\BackupDate.vbs" echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER\Control Panel\International\sShortDate")
for /f %%a in ('cscript /nologo "%temp%\BackupDate.vbs"') do (
  set "RegDateOld=%%a"
)
>"%temp%\UnifyDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\UnifyDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "yyyy-M-d", "REG_SZ"
cscript /nologo "%temp%\UnifyDate.vbs"
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
  set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstDate%" (
    if exist "%%a" (
      echo del /f /q "%%a"
    )
  )
)
>"%temp%\RecoverDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%\RecoverDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER\Control Panel\International\sShortDate", "%RegDateOld%", "REG_SZ"
cscript /nologo "%temp%\RecoverDate.vbs"
pause
【方案四】删除指定路径下指定天数之前（以文件的创建日期为准）的文件：BAT + REG + Ritchie Lawrence 日期函数
复制内容到剪贴板代码:
@echo off
::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了 Ritchie Lawrence 的日期函数进行日期计算
::日期转换的核心算法请参考http://bbs.
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%

for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
  call :CompareTime "%%a"
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

:CompareTime
for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
  if "%%h" leq "%DstDate%" (
    if exist %1 (
      echo del /a /f /q %1
    )
  )
  goto :eof
)
【方案五】删除指定路径下指定天数之前（以文件的修改日期为准）的文件：forfiles
复制内容到剪贴板代码:
@echo off
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例需要Win2003/Vista/Win7系统自带的forfiles命令的支持

rem 指定待删除文件的存放路径
set SrcDir=C:\Test\BatHome
rem 指定天数
set DaysAgo=1

forfiles /p %SrcDir% /s /m *.* /d -%DaysAgo% /c "cmd /c echo del /f /q /a @path"
pause

听说有这么多听说有人试过我自己懒就不试了

#4

pgy2009-10-24 17:59

反对私权，打倒官僚资本主义

打倒老静，换我来当管理员

[ 本帖最后由 pgy 于 2009-10-24 18:00 编辑 ]

#5

forever742009-10-24 18:12

这么具体的问题，根本不用考虑通用性，我倾向于C语言写个exe，执行之。

#6

wokaokeji02009-10-24 18:22

LZ 能不能分享一下备份的批处理程序

#7

静夜思2009-10-24 18:32

回复 3楼 aspic

谢谢提供这么详细的方案，貌似只有第四个方案是根据文件的创建时间判断的，其他的根据修改时间判断的，很多文件备份以后修改时间还是被复制文件的修改时间，这样会删除新备份的文件。另外是需要删除30天前的文件夹及其里面的文件，而不是删除30天前的文件，也就是说只要判断形如数据库备份_20090924 这一层的文件夹就可以了，不需要判断里面的子文件夹。

#8

静夜思2009-10-24 18:35

以下是引用forever74在2009-10-24 18:12:59的发言：

这么具体的问题，根本不用考虑通用性，我倾向于C语言写个exe，执行之。

如果用DOS命令实在没有合适的方案，就用程序了。主要是考虑DOS更方便一些，只一个文件，也不用编译

#9

静夜思2009-10-24 18:40

以下是引用wokaokeji0在2009-10-24 18:22:04的发言：

LZ 能不能分享一下备份的批处理程序

程序代码：

echo off

net stop mysql

set fromdir=G:\Program Files\mysql\data\bccn
set todir=G:\论坛数据库\
set mydir=%todir%mysql_data_%date:~0,4%%date:~5,2%%date:~8,2%
md %mydir%
xcopy %fromdir%\* %mydir% /e

net start mysql

G:\Program Files\mysql\data\bccn 和 G:\论坛数据库\ 分别为备份的源路径和目标路径。
代码中的路径只是示例

#10

wokaokeji02009-10-24 18:44

我到有个想法
1.用 dir /b>>tem.txt

然后用for 循环
2.处理tem.txt中的后几位字符
3.和当前日期比较
4.删除

不可是否可行

#11

静夜思2009-10-24 18:47

以下是引用wokaokeji0在2009-10-24 18:44:40的发言：

我到有个想法
1.用 dir /b>>tem.txt

然后用for 循环
    2.处理tem.txt中的后几位字符
    3.和当前日期比较
4.删除

不可是否可行

我也是这么想的，遍历子文件夹，然后根据文件夹名判断删除，具体怎么实现不会啊

#12

evergogo2009-10-24 19:01

我想把电脑砸了！

#13

lonmaor2009-10-24 19:54

没用过ForFile命令，但知道删除文件夹命令是deltree。给一条猜想命令，当小白鼠用下。

forfiles /p "G:\论坛数据库" /s /m *.* /d -30 /c "cmd /c deltree /y @path"

#14

不说也罢2009-10-24 21:06

程序代码：

@echo off
title 编程论坛批量删除备份数据库DOS程序                      By：不说也罢
color 37

:First
cls
echo.
echo         欢迎使用编程论坛批量删除备份数据库DOS程序
echo.
echo                    制作：不说也罢
echo.
echo.
echo  本程序是应编程论坛管理员“静夜思”要求所特别制作，请勿删除作者名字。
echo.
echo  目录规则如从数据库备份_19990101 到数据库备份_29991231 之间的所有循环目录。
echo  注意：年份和日期都是四位数字。
echo.
goto Date

:Date
echo.
set /p m=请输入四位数的年(如2009)  ：
echo.
set /p d1=请输入起始日期(如0101)   ：
set /p d2=请输入终止日期(如1231)   ：
echo.
echo 继续操作将删除当前目录下从数据库备份_%m%%d1% 到数据库备份_%m%%d2% 之间的所有目录。
echo.
set /p go=你确认继续下一步操作吗？(Y/N)：
if %go%==y goto Do else goto Begin
if %go%==Y goto Do else goto Begin
goto Begin

:Begin
echo.
set /p go=您要继续执行批量删除操作吗？(Y/N)：
if %go%==y goto Date else goto Begin
if %go%==Y goto Date else else goto Begin
exit

:Do
echo.
echo 正在执行删除操作，请稍后...
  for /l %%i in (%d1%,1,%d2%) do if %%i LSS 1000 (rd 数据库备份_%m%%j%0%%i /s /q) else rd 数据库备份_%m%%%i /s /q
echo.
echo 删除目录操作执行完毕，请检查执行效果!
echo.
goto Begin

请将上述代码存为.bat文件，放在“G:\论坛数据库”目录下，运行即可.对于只读文件夹能否删除，我没有测试。呵呵。

[ 本帖最后由不说也罢于 2009-10-24 21:21 编辑 ]

#15

小勇122009-10-24 21:52

o(∩_∩)o...哈哈，老大去www.问问吧，那里一定会找到答案的

#16

newCpp2009-10-24 23:08

哇塞，都是高手啊

#17

cosdos2009-10-25 00:46

用程序处理日期方便。
不过确实脚本比较好。

#18

zyqf2009-10-25 03:44

方法到是很多啊！！可惜我也不懂这批处理！！有时间好好学学！

#19

lonmaor2009-10-25 09:18

突然发现deltree命令被取消了，取而代之的是rd /s

#20

cosdos2009-10-25 11:51

忘了月份是从 1 开始的。计算中用了 0 开始

============= 删除 =============

[ 本帖最后由 cosdos 于 2009-10-25 14:21 编辑 ]

#21

cosdos2009-10-25 11:56

:: cosdos 2009/10/25
:: --- 以Windows当前系统日期为基础。
:: --- 例当前系统日期：2009/10/25，则删除
:: --- 所有以“数据库备份_”开头，后缀日期
:: --- 小于等于“20090925”的所有文件加。

@Echo off
Setlocal EnableDelayedExpansion
Title 删除当前目录中，上个月的“数据库备份_”文件夹
:: cosdos 2009/10/25
Call :main
Pause
Exit

:LastMonth
    Set /a yyyy=%1+10000
    Set /a mm=%2+100
    Set /a dd=%3+100
    If "%2" == "01"  (
        Set mm=112 & Goto year
    ) else (
        Set /a mm-=1 & Set lastmonthday=%yyyy:~1,4%!mm:~1,2!%dd:~1,2%
    )
    Exit /b
    :year
    Set /a yyyy-=1
    Set lastmonthday=%yyyy:~1,4%%mm:~1,2%%dd:~1,2%
    Exit /b

:main
    Set myfolder=数据库备份_
    Set yyyy=%date:~0,4%
    Set mm=%date:~5,2%
    Set dd=%date:~8,2%
    Call:LastMonth %yyyy% %mm% %dd%
    Echo.
    Echo 删除当前目录中，“%myfolder%%lastmonthday%”之前的文件夹
    For /d %%i in (数据库备份_*) do (
        Set folderdate=%%i&&if /i !folderdate:~-8! lEQ %lastmonthday% rd /s /q %%i
    )
    Exit /b

[ 本帖最后由 cosdos 于 2009-10-25 13:41 编辑 ]

#22

黄玉宏2009-10-26 10:18

DOS中删除指定文件夹命令为：Deltree，删除时会有参数提醒！它不管该文件夹中有无其它文件或子文件夹，都会删除！它是仅次于Format命令的删除命令！安装系统时常用到它！
黄玉宏二○○九年十月二十六日

#23

zqb78992009-10-26 12:38

都是高手

高级DOS命令
以前学过一点
现在都忘了

#24

静夜思2009-10-26 13:34

结贴了，谢谢大家回复，最佳答案在21楼
14楼可能理解错我的意思了，这个批处理文件是需要计划任务自动执行的，所以日期就是取系统当前日期做对比，不是需要手动输入的。

#25

fuyang1632009-10-28 08:28

试试这个：在dos窗口输入命令： DEL G:\论坛数据库

#26

pyfxl2009-11-06 10:05

顶起，下了，谢谢。

#27

liu92072009-11-06 12:39

学习