送给用 EditPlus 或 Programmer's Notepad 等编辑器写代码的朋友！

" My vimrc file
" Create by StarWing
" Setting frim vimrc_example {{{
" An example for a vimrc file.
"
" Maintainer:    Bram Moolenaar <Bram@ Last change:    2008 Jul 02
"
" To use it, copy it to
"     for Unix and OS/2:  ~/.vimrc
"          for Amiga:  s:.vimrc
"  for MS-DOS and Win32:  $VIM\_vimrc
"        for OpenVMS:  sys$login:.vimrc

" When started as "evim", evim.vim will already have done these settings.
if v:progname =~? "evim"
    finish
endif

" Use Vim settings, rather then Vi settings (much better!).
" This must be first, because it changes other options as a side effect.
set nocompatible

" allow backspacing over everything in insert mode
set backspace=indent,eol,start

if has("vms")
    set nobackup        " do not keep a backup file, use versions instead
else
    set backup        " keep a backup file
endif
set history=50        " keep 50 lines of command line history
set ruler        " show the cursor position all the time
set showcmd        " display incomplete commands
set incsearch        " do incremental searching

" For Win32 GUI: remove 't' flag from 'guioptions': no tearoff menu entries
" let &guioptions = substitute(&guioptions, "t", "", "g")

" Don't use Ex mode, use Q for formatting
map Q gq

" CTRL-U in insert mode deletes a lot.  Use CTRL-G u to first break undo,
" so that you can undo CTRL-U after inserting a line break.
inoremap <C-U> <C-G>u<C-U>

" In many terminal emulators the mouse works just fine, thus enable it.
if has('mouse')
    set mouse=a
endif

" Switch syntax highlighting on, when the terminal has colors
" Also switch on highlighting the last used search pattern.
if &t_Co > 2 || has("gui_running")
    syntax on
    set hlsearch
endif

" Only do this part when compiled with support for autocommands.
if has("autocmd")

    " Enable file type detection.
    " Use the default filetype settings, so that mail gets 'tw' set to 72,
    " 'cindent' is on in C files, etc.
    " Also load indent files, to automatically do language-dependent indenting.
    filetype plugin indent on

    " Put these in an autocmd group, so that we can delete them easily.
    augroup vimrcEx
        au!

        " For all text files set 'textwidth' to 78 characters.
        autocmd FileType text setlocal textwidth=78

        " When editing a file, always jump to the last known cursor position.
        " Don't do it when the position is invalid or when inside an event handler
        " (happens when dropping a file on gvim).
        " Also don't do it when the mark is in the first line, that is the default
        " position when opening a file.
        autocmd BufReadPost *
                    \ if line("'\"") > 1 && line("'\"") <= line("$") |
                    \   exe "normal! g`\"" |
                    \ endif

    augroup END

else

    set autoindent        " always set autoindenting on

endif " has("autocmd")

" Convenient command to see the difference between the current buffer and the
" file it was loaded from, thus the changes you made.
" Only define it when not defined already.
if !exists(":DiffOrig")
    command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
                \ | wincmd p | diffthis
endif


" }}}

" My Own Setting
" Time : 2008年 09月 02日 星期二 13:16:56 CST
" Global setting {{{

if has("gui_running")
    colorscheme evening "设置颜色主题
    set guifont=Courier\ New\ 9 "显示字体
endif

set autoread "自动读写在外部改变的文件
set clipboard+=unnamed "使用"*寄存器作剪切粘贴工作
set completeopt=longest,menu "自动完成设定
set fileencodings=ucs-bom,utf-8,gbk "尝试打开文件的编码

" 载入在Windows下的特殊设置
source $VIM/tools/win.vim

" }}}
" Global maps {{{

imap <F3> <ESC><F3>
nmap <F3> :%s///g<LEFT><LEFT><LEFT>
map <F4> :noh<CR>

" 全部复制
nmap zy gg"+yG
" 全部粘贴
nmap zp ggVG"+p
" 得到日期
nmap gl A<C-R>=system("date")<CR><BS><ESC>
" 启用WinManager
map gc :WMToggle<CR>


"}}}
" auto commands for C/C++ file {{{

if has('autocmd')
    augroup C_env_cmd
        au BufFilePost *.c setf c | setl modified
        au BufFilePost *.{cpp,C,cc,h,hpp} setf cpp | setl modified
        au FileType c,cpp call Set_env_for_C()
    augroup END
endif

" }}}
" feature that has eval functon {{{
if has('eval')
    " Commands for CC flags {{{

    command UseGtk let cc_flags='`pkg-config --libs --cflags gtk+-2.0`'
    command UseGL let cc_flags='-L/usr/X11R6/lib -lglut -lGLU -lGL -lX11
                \ -lXext -lXmu -lXi -lm'


    " }}}
    " Global vars for plugins and functions {{{
    "
    let g:astyle_flags = '-npUt --style=ansi --mode=c'
    let g:cc_flags = '-Wall -lm -O2'

    let g:ctags_file = './tags.current'
    let g:ctags_flags = '--c++-kinds=+p --fields=+ialS --extra=+q'

    let g:winManagerWindowLayout = 'FileExplorer|TagList'

    let g:miniBufExplMapCTabSwitchBufs = 1
    let g:miniBufExplMapWindowNavVim = 1
    let g:miniBufExplorerMoreThanOne = 2

    let g:SuperTabRetainCompletionType = 2
    let g:SuperTabDefaultCompletionType = '<C-X><C-O>'

    let OmniCpp_GlobalScopeSearch = 1  " 0 or 1
    let OmniCpp_NamespaceSearch = 1   " 0 ,  1 or 2
    let OmniCpp_DisplayMode = 1
    let OmniCpp_ShowScopeInAbbr = 0
    let OmniCpp_ShowPrototypeInAbbr = 1
    let OmniCpp_ShowAccess = 1
    let OmniCpp_MayCompleteDot = 1
    let OmniCpp_MayCompleteArrow = 1
    let OmniCpp_MayCompleteScope = 1

    let Tlist_Show_One_File = 1
    let Tlist_Exit_OnlyWindow = 1

    let g:prj_dir = '~/Projects/misc'
    if argc() == 0
        if isdirectory(expand(g:prj_dir))
            exec 'cd '.expand(g:prj_dir)
        endif
    else
        exec 'cd %:p:h'
    endif


    " }}}
    " Functions for progaming {{{
    " Find C/C++ file in current window {{{
    "
    func! Find_C_File()
        let s:thiswin = winnr()
        while 1
            if &filetype == 'c' || &filetype == 'cpp'
                return 0
            endif
            exec "normal! \<C-W>w"
            if s:thiswin == winnr()
                echo "Can't find C/C++ file, have you open it?"
                return 1
            endif
        endwhile
    endfunc    "}}}
    "Compile C/C++ file,smart analyze the filetype {{{
    "
    func! Compile()
        if Save_and_Update_tags()
            return 1
        endif

        let cc = (&filetype=='c' ? 'gcc' : 'g++')
        let msg = ['Compiling '.&filetype.' program '.bufname('').' ...']
        redraw | echo msg[0]
        let msg += [cc.' -o "'.expand("%:r").'" '.g:cc_flags.' "'.expand('%').'"']
        let msg += split(system(msg[1]),"\<NL>",1)
        let msg += ['Compile completed. '.cc.' return '.v:shell_error]
        call writefile(msg,&errorfile)

        silent cgetfile
        silent cwindow

        redraw
        if v:shell_error == 0
            echo 'Compile Success!'
        else
            echo 'Compile fail, debug please!'
        endif
        return v:shell_error
    endfunc "}}}
    "A simple Implement of compile and run {{{
    func! Compile_and_Run()
        if Find_C_File() || (&modified && Compile())
            return
        endif
        exec '!'.expand("%:p:r")
    endfunc "}}}
    " Save file, and update tags using ctags {{{
    "
    func! Save_and_Update_tags()
        if Find_C_File()
            return 1
        endif

        try
            if &modified
                write
            endif
        catch /E13/
            echo 'Error: same file exists, Still Save?(y/n)'
            if nr2char(getchar()) ==? 'y'
                write!
            else
                redraw | echo 'Done nothing.'
                return 1
            endif
        endtry

        call system('ctags '.g:ctags_flags.' -f"'
                    \ .g:ctags_file.'" "'.expand("%").'"')
        TlistUpdate
        redraw | echo 'Update tags completed!'
    endfunc "}}}
    " Run AStyle filter on C/C++ file {{{
    "
    func! AStyle_on_file()
        if Find_C_File()
            return 1
        endif

        set modified
        exec '%!astyle '.g:astyle_flags
        exec "normal ''zz"
        if !Save_and_Update_tags()
            redraw | echo 'Save and Artistic Style completed!'
        endif
    endfunc "}}}
    "Set the C development envirnment {{{
    "
    func! Set_env_for_C()

        if exists("g:ctags_file")
            exec 'setl tags+=~/.vim/systags,'.escape(g:ctags_file,' ')
        endif

        if exists("g:astyle_flags")
            exec 'setl equalprg=astyle\ '.escape(g:astyle_flags,' ')
        endif

        setl cindent "使用C方式的缩进
        setl errorformat+=%f:%m "让错误提示处理只有文件名的情况
        setl expandtab "用空格代替TAB字符
        setl foldcolumn=2 "折叠栏宽度为1
        setl foldlevel=100  "启动 vim 时不要自动折叠代码
        setl foldmethod=syntax "语法方式折叠
        setl number "打开行号
        setl shiftwidth=4 "缩进大小
        setl smarttab "使用智能TAB
        setl tabstop=4 "TAB大小

        " 编译，运行，更新tags
        map<silent> <A-c> :call Compile()<CR>
        map<silent> <A-r> :call Compile_and_Run()<CR>
        map<silent> <A-u> :call AStyle_on_file()<CR>

        " 错误遍历
        map<silent> <F5> :call Compile_and_Run()<CR>
        map<silent> <F6> :call AStyle_on_file()<CR>
        map<silent> <F7> :silent! cp<CR>
        map<silent> <F8> :silent! cn<CR>

        " **** 常用缩写 **** "
        map<silent> <F10> gf
        map<silent> <F11> <C-O>

        " 打开头文件，在头文件/源文件中切换，文件模板
        map<silent> <F12> :A<CR>

        " Insert模式下的映射
        imap<A-c> <ESC><A-c>
        imap<A-r> <ESC><A-r>
        imap<A-u> <ESC><A-u>i
        imap<F5> <ESC><F5>i
        imap<F6> <ESC><F6>i
        imap<F7> <ESC><F7>i
        imap<F8> <ESC><F8>i

        iabbrev<buffer> #b /*********************************************
        iabbrev<buffer> #e <BS>*******************************************/
        iabbrev<buffer> #fheader# /*********************************************<CR>File Name:<CR>Author:<CR>Date:<C-R>=system("date")<CR>Version:<CR><BS>*******************************************/<UP><UP><UP><UP><C-R>=bufname("")<CR>
        iabbrev<buffer> #tc# #include <stdio.h><CR>#include <stdlib.h><CR><CR>int main(void)<CR>{<CR>return 0;<CR>}<CR><ESC>kkko
        iabbrev<buffer> #tcpp# #include<iostream><CR>using namespace std;<CR><CR>int main()<CR>{<CR>return 0;<CR>}<CR><Esc>kkko
        iabbrev<buffer> #i #include

        if has("gui_running")
            if &columns < 86
                let &columns = 86
            endif
            if &lines < 25
                let &lines = 25
            endif
        endif
    endfunc "}}}
    " }}}
endif
" }}}

"My vimrc History {{{
"================================================================================
" My vimrc History:
"     1.0.0 o Create this Script File.
"     1.0.1 o Add vimrc_example in this file.
"           o yank the setting for C/C++ file into a single function.
"     1.0.2 o Find A better way to solve the question that cursor is not in
"             a C/C++ file window.
"           o Use file filter to run astyle, not a system() function.
"           o Add folds in file.
"           o Change Script language into English.
"    1.0.3 o Recode functions, and separated eval-requires code with other
"               codes.
"
"================================================================================
" }}}
" vim:ft=vim:fdm=marker:ff=unix:nowrap:tabstop=4:shiftwidth=4:softtabstop=4:smarttab:shiftround:expandtab:nu