老罗的窗口程序代码``请高手把每个步骤的意思说给小菜听下！谢谢

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Sample code for < Win32ASM Programming 2nd Edition>
; by 罗云彬, http://asm.
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; FirstWindow.asm
; 窗口程序的模板代码
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 使用 nmake 或下列命令进行编译和链接:
; ml /c /coff FirstWindow.asm
; Link /subsystem:windows FirstWindow.obj
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
        .386
        .model flat,stdcall
        option casemap:none
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include        windows.inc
include        gdi32.inc
includelib    gdi32.lib
include        user32.inc
includelib    user32.lib
include        kernel32.inc
includelib    kernel32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 数据段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
        .data?
hInstance    dd        ?
hWinMain    dd        ?

        .const
szClassName    db    'MyClass',0
szCaptionMain    db    'My first Window !',0
szText        db    'Win32 Assembly, Simple and powerful !',0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 代码段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
        .code
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 窗口过程
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_ProcWinMain    proc    uses ebx edi esi hWnd,uMsg,wParam,lParam    ;----------消息处理函数开始
        local    @stPs:PAINTSTRUCT
        local    @stRect:RECT
        local    @hDc

        mov    eax,uMsg
;********************************************************************
        .if    eax ==    WM_PAINT                            ;----------当窗口受到WM_PAINT这个消息时的动作
            invoke    BeginPaint,hWnd,addr @stPs ;----------与EndPaint配合，申请一个设备句柄
            mov    @hDc,eax                      ;----------将申请的句柄保存到@hDc

            invoke    GetClientRect,hWnd,addr @stRect
            invoke    DrawText,@hDc,addr szText,-1,\        ;----------用DrawText在设备上输出文字
                addr @stRect,\
                DT_SINGLELINE or DT_CENTER or DT_VCENTER

            invoke    EndPaint,hWnd,addr @stPs
;********************************************************************
        .elseif    eax ==    WM_CLOSE  ;----------当窗口受到WM_CLOSE这个消息时的动作
            invoke    DestroyWindow,hWinMain
            invoke    PostQuitMessage,NULL
;********************************************************************
        .else
            invoke    DefWindowProc,hWnd,uMsg,wParam,lParam ;----------其他消息的默认处理函数
            ret
        .endif
;********************************************************************
        xor    eax,eax
        ret

_ProcWinMain    endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WinMain    proc             ;----------窗口的主函数，负责注册窗体、显示窗体、建立消息循环
        local    @stWndClass:WNDCLASSEX
        local    @stMsg:MSG

        invoke    GetModuleHandle,NULL ;----------取得本程序的句柄
        mov    hInstance,eax
        invoke    RtlZeroMemory,addr @stWndClass,sizeof @stWndClass
;********************************************************************
; 注册窗口类
;********************************************************************
        invoke    LoadCursor,0,IDC_ARROW
        mov    @stWndClass.hCursor,eax
        push    hInstance
        pop    @stWndClass.hInstance
        mov    @stWndClass.cbSize,sizeof WNDCLASSEX
        mov    @stWndClass.style,CS_HREDRAW or CS_VREDRAW
        mov    @stWndClass.lpfnWndProc,offset _ProcWinMain
        mov    @stWndClass.hbrBackground,COLOR_WINDOW + 1
        mov    @stWndClass.lpszClassName,offset szClassName
        invoke    RegisterClassEx,addr @stWndClass
;********************************************************************
; 建立并显示窗口
;********************************************************************
        invoke    CreateWindowEx,WS_EX_CLIENTEDGE,offset szClassName,offset szCaptionMain,\
            WS_OVERLAPPEDWINDOW,\
            100,100,600,400,\
            NULL,NULL,hInstance,NULL
        mov    hWinMain,eax
        invoke    ShowWindow,hWinMain,SW_SHOWNORMAL
        invoke    UpdateWindow,hWinMain
;********************************************************************
; 消息循环
;********************************************************************
        .while    TRUE
            invoke    GetMessage,addr @stMsg,NULL,0,0
            .break    .if eax    == 0
            invoke    TranslateMessage,addr @stMsg
            invoke    DispatchMessage,addr @stMsg
        .endw
        ret

_WinMain    endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:                          ;----------整个程序从这里开始
        call    _WinMain
        invoke    ExitProcess,NULL
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
        end    start

难得看到有学win32汇编的了.

学习方法欠缺一点点.

如果仅是学习win32环境下的汇编,在刚开始的阶段,以invoke为着眼点,弄清楚后面的API是做什么的, 至于参数,不要记数量,但是要知道参数的用途和参数的值在什么时候从什么地方得到的.

罗云彬的书是经典,这是书里的第一个程序,静下心去,照几天的研究, 抄几遍, 打电脑上几遍, 自然会明白了.

以CPU的角度,按照最机械,最笨的想法去学习win32汇编.

推荐用masmplus敲代码,大大减轻查API参数的劳动量了.

罗云彬的书上对这个程序解释得蛮清楚的呀。
建议LZ要反复阅读几遍。
先弄清整个程序的“框架”，然后弄清每个API、每条指令的作用，可能就明白了。
我是这么理解的，请参考：
这个程序可以分为三个部分：（注：指的是“.code”段）
第一部分：
start:
        call  _WinMain
        invoke ExitProcess,NULL
       end   start
======================================
第二部分：
_WinMain  proc
       ... ...
       ... ...
_WinMain  endp
=====================================
第三部分：
_ProcWinMain  proc  ... ...
       ... ...
       ... ...
_ProcWinMain  endp
=====================================
第一部分很简单，就是CALL第二部分的。
那第二部分被CALL了之后，它就开始工作了，如注册窗口类、建立并显示窗口、获取消息、派送消息等。
第二部分在工作的过程中，它会向第三部分发送各种消息。
而第三部分就是处理消息的，从.if  .elseif  等等可以看出，它会针对不同的消息采取不同的措施。
在_ProcWinMain 的开头，有这样的“uses ebx edi esi hWnd,uMsg,wParam,lParam ”，这里的“hWnd,uMsg,wParam,lParam  ”就是每个消息的参数，或者说是MSG结构的前面4个成员。它们的值由不同的消息决定的 ，是给_ProcWinMain 这个子程序用的。

我觉得就是这样，不知道理解得对不对。